# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (AUR): Lex Black <autumn-wind at web dot de>
# Contributor (AUR): xnitropl <xnitropl at gmail dot com>
# Contributor (AUR): Anton Larionov <diffident dot cat at gmail dot com>

# # I maintain this because:
# AUR version uses /opt
# AUR version uses .ico

pkgname=7kaa
pkgver=2.15.2
pkgrel=2
pkgdesc='Seven Kingdoms: Ancient Adversaries is a real-time strategy (RTS) computer game developed by Trevor Chan'
url='https://7kfans.com/'
arch=('i686' 'x86_64')
license=('GPL2')
depends=('openal' 'desktop-file-utils' 'enet' 'gcc-libs' 'sdl2')
optdepends=('7kaa-music: for ingame music')
conflicts=('7kaa-data')
provides=('7kaa-data')
source=("https://github.com/the3dfxdude/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "${pkgname}.sh"
        "${pkgname}.desktop"
        "${pkgname}.png"
        "buffer_overflow.patch")
md5sums=('abd3648aec3b8337a16f22de43ce9b19'
         '78e098c8e8b2467f02da886f8bc431a0'
         '880d2760bdb02f8f73552e13f3a1a5a9'
         'a44784360325c94b605de06f7154d121'
         '624e73ece72789f3aeff3b6497cabb77')

prepare() {
  cd ${pkgname}-${pkgver}
  # Fix https://github.com/the3dfxdude/7kaa/issues/172
  patch -Np1 -i "${srcdir}"/buffer_overflow.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure
  make
}

package() {
  # install data files
  install -dm755 "${pkgdir}/usr/lib/7kaa/"
  cd "${srcdir}/$pkgname-$pkgver/data/"
  cp -r {ENCYC,ENCYC2,IMAGE,RESOURCE,SCENARI2,SCENARIO,SOUND,SPRITE,TUTORIAL} "${pkgdir}/usr/lib/7kaa/"

  # fix permissions
  cd "${pkgdir}/usr/lib/7kaa/"
  find . -type d -exec chmod 755 {} \;

  # copy readme
  install -D -m644 "${srcdir}/$pkgname-$pkgver/README" "${pkgdir}/usr/share/doc/7kaa/README"

  # main file
  install -dm755 "${pkgdir}/usr/lib/${pkgname}/"
  install -D -m755 "${srcdir}/${pkgname}-${pkgver}/src/${pkgname}" "${pkgdir}/usr/lib/${pkgname}/${pkgname}"

  # bash script
  install -D -m755 "$srcdir/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"

  # desktop entry
  install -D -m644 "$srcdir/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -D -m644 "${srcdir}/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}