# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Kyle Keen <keenerd@gmail.com>

# # I maintain this because:
# Arch version is not BN
# Arch version has non-functional desktop file
# Arch version lacks additional optimization and hardening flags
# Arch version lacks the MSX++UnDeadPeopleEdition tileset
# Arch version lacks the @ soundpack
# Arch version lacks the CO.AG musicpack
# Arch version lacks numerous bugfixes I created
# Arch version has some vanilla balancing changes I disagree with

pkgbase=cataclysm-bn
pkgname=(cataclysm-bn cataclysm-bn-tiles)
pkgname=cataclysm-bn
_pkgname=Cataclysm-BN-cbn-experimental
pkgver=202304032237
_pkgver=2023-04-03-2237
pkgrel=2
pkgdesc="A post-apocalyptic roguelike."
#url="http://cataclysmrl.blogspot.com/"
#url="http://www.cataclysm.glyphgryph.com/"
#url="http://en.cataclysmdda.com/"
url="https://github.com/cataclysmbnteam/Cataclysm-BN"
arch=('x86_64' 'aarch64')
license=("CCPL:by-sa")
options=('lto')
depends=('ncurses' 'hicolor-icon-theme' 'gettext')
makedepends=('sdl2_image' 'sdl2_ttf' 'sdl2_mixer' 'freetype2' 'astyle')
source=("$pkgname-$_pkgver.tar.gz::https://github.com/cataclysmbnteam/Cataclysm-BN/archive/refs/tags/cbn-experimental-$_pkgver.tar.gz"
        "cataclysm-bn.desktop"
        "cataclysm-bn-tiles.desktop"
        "icon_128x128.png"

        "revert-01_removed-traits.patch"
        "revert-02_revert-book-revamp.patch"
        "revert-03_generic-nv.patch"
        "revert-04_telescopic-lenses.patch"
        "revert-06_Obsolete-useless-hub01-basement-1457.patch"
        "revert-07_Remove-handload-quality-distinction-1481.patch"
        "revert-08_undo-rifle-balance-pass.patch"
        "revert-09_undo-yet-more-ammo-balancing.patch"
        "revert-10_still-another-ammo-patch-to-undo.patch"
        "revert-11_Obsoletion-and-removal-of-useless-bathroom-fluff-247.patch"

        "ammo-01_inconsistent-ammo-names.patch"
        "ammo-02_fix-20x66mm-loudness.patch"
        "ammo-03_fix-reloaded-50bmg.patch"
        "ammo-05_22-casings-can-stack.patch"
        "ammo-06_fix-bp-scrap-not-being-bp.patch"
        "ammo-10_ammo-order-fix.patch"
        "ammo-11_fix-volume-40mm.patch"

        "armor-01_ankle-ammo-pouch-is-not-a-backpack.patch"
        "armor-02_fix-survivor-fingerless-gloves-warmth.patch"

        "bionics-01_npc-can-use-more-bionics.patch"
        "bionics-02_fix-bionic-prices.patch"

        "faction-01_more-factions.patch"
        "faction-03_fix-food-supply-calculations.patch"

        "factioncamp-01_remove-legacy-recruiting-penalty.patch"

        "foods-01_fix-food-materials.patch"
        "foods-02_fix-food-naming.patch"
        "foods-03_fix-mutant-bad-taste.patch"
        "foods-04_allow-canned-corn-as-veggy.patch"

        "itemgroups-01_hk46-is-milspec.patch"
        "itemgroups-02_add-missing-mre.patch"
        "itemgroups-03_fix-shelter-batteries.patch"

        "meds-01_antibiotics-unhealthy.patch"

        "migration-01_remove-ucp.patch"

        "mission-01_typos.patch"

        "monsters-01_medical-zombies-called-zombies.patch"

        "mutations-01_nerf-lightstep.patch"
        "mutations-02_fix-evac3-background-visible.patch"
        "mutations-03_eye-colours.patch"

        "npc-01_isherwood-update.patch"
        "npc-02_tacoma-update.patch"
        "npc-03_godco-update.patch"
        "npc-04_island-prison-update.patch"
        "npc-05_kindred-update.patch"
        "npc-06_lapin-update.patch"
        "npc-07_lighthouse-family_v2.patch"
        "npc-08_nurse-takes-more-meds.patch"
        "npc-09_broker-takes-more-foods.patch"
        "npc-10_bunker-merchant.patch"
        "npc-11_npcs-reload-gas-mask.patch"
        "npc-12_fix-eddie-requiring-1000-clay.patch"
        "npc-20_dialogue-fixes.patch"

        "recipes-01_4570-dragon-can-be-dismantled.patch"

        "terrain-02_fix-doors-for-npcs.patch"
        "terrain-03_tacoma-clinic-add-missing-floor.patch"
        "terrain-04_lumbermill-gasoline-not-spilled.patch"
        "terrain-05_community-garden-fertilizer-not-spilled.patch"
        "terrain-07_rehide-redacted.patch"
        "terrain-09_make-firestation-shelter-wells-npc-drinkable.patch"
        "terrain-10_fix-milbase_minefield.patch"
        "terrain-11_clean-up-map-extras.patch"
        "terrain-12_add_fmc_stairs.patch"

        "tools-01_foldable-bottle-is-container.patch"
        "tools-02_vacutainer-is-not-a-weapon.patch"
        "tools-03_shears-use-light-battery.patch"
        "tools-04_normalize-drone-volume.patch"

        "vehicles-01_portable-generator-engine.patch"
        "vehicles-02_fix-fbi-car-name.patch"
        "vehicles-03_black-box-can-be-installed.patch"

        "weapon-01_fix-v29-copy-from.patch"
        "weapon-02_Fix-usp45-load-order.patch"

        "etc-01_fix-rubbersplosion.patch"
        "etc-02_add-missing-price-postapoc.patch"
        "etc-03_fix-abstracts.patch"

        "jc_radio-can-use-ups.patch"
        "jc_ammo-loudness-ap-times-2.patch"
        "jc_allow-bio-firestarter-on-smoker.patch"
        "jc_stop-non-faction-npc-sleep-depirvation.patch"
        "jc_stop-non-faction-npc-malnourishment.patch"
        "jc_stop-sleeping-on-tables.patch"
        "jc_allow-hacker-laptop.patch"
        "jc_more-military-base-overmap.patch"
        "jc_npc-eat-from-further-camp.patch"
        "jc_reduced-kcal-during-sleep.patch"
        
        "vampirism.patch"

        "cataclysm-dda-tileset_undeadpeople.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-tileset_undeadpeople.git/snapshot/cataclysm-dda-tileset_undeadpeople-master.tar.xz"
        "cataclysm-dda-mod_battle-maid-redone-tileset.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-mod_battle-maid-redone-tileset.git/snapshot/cataclysm-dda-mod_battle-maid-redone-tileset-master.tar.xz"
        "cataclysm-dda-soundpack_jcsoundpack.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-soundpack_jcsoundpack.git/snapshot/cataclysm-dda-soundpack_jcsoundpack-master.tar.xz"
        "cataclysm-dda-musicpack_coag-musicpack.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-musicpack_coag-musicpack.git/snapshot/cataclysm-dda-musicpack_coag-musicpack-master.tar.xz"
        )
b2sums=('88c6f4768236b9c89609373b3632b5bc5f440b8bf47f9053053f36539be21a69c4e9310ef596e7a24ee157b9db3bdd6c6d26e90dcb570fa7a87e3b5d7380280a'
        '069ecde58859b3d44cd687c4b6e718610cefb693ff86e66f199ebfb1b3072023ad2b6f0c28e27ef9c1ce4997f6a5b2ca0d45046996b3ff35a4aeaeb1a7cf9421'
        'ad88bc6c1e3c8183a313b5eec42f98d6956afea349feff34a86e4536c9921fa99d2594282caf27de8ebb7ffb56376ed2e76d572227bfd6d8173c7bb1f01e23b8'
        '6f70e90359a14e4839d9a2683debb88850e5dd387add911ad68fd87e5512cfcdd435da63e1e370358153673fd5a72a9b1e9c94f1979edb7948b4da8c82407bad'
        '1de2211ce631a43e343de2c630e525cc46f30be4983737a5c046e2e7bd4d2d67a5b31a57ba78f58c980d1ed6d26f90683fc4fa91530ceddf6b8d5012a31e8e9b'
        'f3549372dec640f5fc51d2c7e2c439e34dc5e9b0cbabfc689d6d449814cfd997413360a363ace85835aec5a1fc2dd8e4bb2c54135fb63f617efdb00565d1616e'
        'e417a1786fbafb685099431f7f9926201ab80636bf3812da67acc341c7ef2b6a3853734d5b8b1bc355acbd5c0bedefb0401f8854aa5cb00032550afc8a7b9ebe'
        '4563b0454c67b003fc1e266345d609d8cce5d60f5d19e9936f441c3b75a98d7c162959286da9507e79def7544675cba8c9e589cca55ed9a1ed261ac608ac7c1a'
        '2d197903715263628e767e867e9b20b9ebd3d85f8983ac8f1e2b534f2b6f8c0470886c79a409f117ad43348aa6aef2a6298925ae27faa32814183ad7677528ac'
        'd6ab568373c3bae4d99e7ef1c80e1c8b1c0e4256610919d3d060d71c202dd40597ea1230b4c00c6ef04960a0da2aa436970943b94e6276725be0bb9d865508f7'
        '0ac92184f85d8b3dceee4a210b2f7f367aeb14c609d468e87205d0eb630e1b6bad6903b863ea61c3a032b665b2316871b6c70aa8508c604a7237a378fae39d92'
        'd62bcb01bcb2934bf405e205a511bd076bc793bb8699dd205a5441afddfe8bbb161f7925de8294c51a528318155af4d2261e2ca2a7a2614d22053d5bbe4359a1'
        '1950d2cacc8697b3f0602f3eb232744fd0f7de4489b7747089abfa8784ec9e4433db4dcdf925d0bc37686ee14d607dcd5345e3db5b5b155a6208bde8b1706e23'
        '80e2ee7966c8e2218f8d2df0a1aa9a3c1512682aa437423892efa7d43a45e51fa71f678e993f6cb9d090470fac73b7e49326df548b638384b20d1224577775a4'
        'ea9e227eff0a9470a06effc35d8e991c0e21d5521e0325317ab36760b5bb3256676fee29dd948fcc7f4b09ce9235c2d859cd22d6839ebf14deb369cdf97b20f0'
        '6dbcf4833dabb68443e50a644cc26309785593f757f7484771a101873aeb02d2e8f3869c0679132a6883ea86bd5fd47494281d0f70dcae9f4bec9b06a7d69b19'
        '124893f23b7d865709fa87a9fade8fb01e596c1f31b0811ab32d5e730e1101c62af672eaf5fe9cdefa338fc25164407023f4c7dcc7cacdb0c86b4713180d345d'
        '67cdb7e097bbb46da5cf04708bc2858b080d1a85742afc4c088da3e4e3fdeb6e4c51240fc5a6b9a1c7d927b30b3d251236e025ee4e5496142a7716d4ba51b82c'
        '2ebc9d61438ef1439a3dcfae7e56f2f4cb1d4410faadd2e018359b6c4711abdcd474f2eeb2d23e531a523caea19ec40d820b60c0b8cdaf04223ca9eed1119ec7'
        '373186c55545b4e747c08db497dae0f1446d2830c862a1b8a0d1bd03d237acc9a4fa8854537c0f485528fc0ef05ec6a2f5e43a42c21689dd85178fb07667b51b'
        '5dd5cb90aab682dfad9c46b1fcbe93294b4d9e40f4c3f30a917b25081f7cfc66baa60adbb81584d622f099761eba0eda8f46d6e49df1f82ec3c50a2da61836b3'
        '0884229f513f843099dbd397d96fd8b37aad2d1ae0aee2771f57f54188241d6ed0ede8750780b9564bd9e3dc8d215039d409081a8eb46ce25b90edb196eb6bf4'
        'f4ad4c90cfcf11af42c6cfc6d2027b21af3f58ac274b9bd0852a52ef60b606476766f194b281f6baf12f81647b384a98f745519bb48bc2e4f5fe03984c7c0e65'
        '172c611008cb8893a8a8cbf83ef929f5727fbf341f3303c6f38749e3742f96ba7352624112ac231a8df7be9031649e41d54cc52152776e52e3a7a620ea8f33e3'
        'ee31032c9d960e4290dea08a97037f8566e35743e949d3d38f6e9ae76a736118d23c34ce7cd1b99d40460047f9fb6e54c52b156587bb76458942139e18dd82d8'
        '1ce956dbcd0af3e16c336ce15995a7df19b8bed78765890304ff9dcaf6d30c602580bef050d6c659fdff945a31dce880f5f4042dfc295cdef44c34155a3e644c'
        '804cea67bb0a2fab62dd9cf633d1959a3fe59b3e24f0c2e01a6db951100fa4426ae946a90a93fa7fd6a7d0ece478633d0091144c2fa776858157edec1310f837'
        'a611964c224c7751c3afeaadb159135e5ed5d87d3ed254be63b4b12450f4f63f414c90f8e29f3d14c0b854f4c9938bf5d12db69d2e258f1947e353302ca07da7'
        'e8caa14c3fdd1c8a6388287811c2df7cb6a0f88c52d6bf21526352decbf1c80a3d143e01ffd04eca9fa31e612d15346157df0ec5242f80b5d601230e4b85d153'
        '32975862668e4c28bf345cf9e2e3a2f754f7d7d50208f1d840e3b2ca47da1c19bcff9bdf6dc841ec803c64fd633b479d1d598ee22119589732f7cff1fa6dd6dd'
        '7da2d555f4b21da6704675400dc97367ff3e6bb60213d86c972b6740f074bcef98482ad7f759ddbee09f67d0ee8687c26c425d697ab586a784385971aec72bb0'
        'b7de805805030014da358902f4d2a387a34aa911a1a581a5d394c79653244e0e4d2a038be486c3eac3fc466fde1df3a519e2c6e4374674c68be9bfee498310a8'
        '76c816df10aceec8f1a7d1356220eb3f00b16fac455e84eb8aefe76db29cd037dc74fb5cfa344b8d283b188951bd100c26e351ce2e27c16c836a547fe2c99e46'
        '417cd957f188b2b06e41d5413bea5f13481c6d5bfa8f184157379d5ac2afa9ba6f7ebc966856f50603f89b9173b6fbfdb3ccf4e3cc0b1bedb53f935591e4a35c'
        'dae75d9cd00f1f3ceabf257f1d82d245ace6582cf7ea98a40c1d1eb9b7e1832cb2a0c13f25c814a05a70931c42a06694a67829ea55554cc680eaa8ddf16c84a8'
        '931ac85c657c1c504de1ea629205b19f79a11acdd7c62cf71b909323ec1588610b1f575bc58ab01c3fbcd334fca8fbc114316570732f55a3f7fb3dd2984cd442'
        'b9bf63ed06aee848fa70adceaf9674e842343e6f92e9a2e57be372814b481d54bdfee602eac9e3c05dc5c8e35ec36146f28491de39b7ea2c8c3a8b9ac80c0354'
        '536c59b274923d36fbfc6dc39ef373a0d1e497422dea6fcdc16cfacb6b9ba421f14c5d7c4db31bab083199d859ff57ae5b19842f95367cfa39059e7156e96093'
        'e466392190e0aa58c02acda287bc8ac6fef30160207d08805ca9acd42b7f024d0680c0a76fcb4f29a7d7ca884920bba3a6714b5ad40f64dd1b40bcf0e2621d26'
        '08f4746882b927bdff6b728630cf1e04a2b79924f694ca2d841e3115c3399feb87a8d363e4d2a0f59179c109cb6be6e840f912aadd44abb0bdb35afd2838cc4d'
        'ab35d6663b864449d46da4a9e1c51e11956ff4c38e16db58c831b71f7b964fc25b0283122dbc8aa0549f240f01c4a910fb5c6c82937258c6b736c05b54bcf768'
        '0793bb7aa67d3989ef093cc17e6d9dd6d2e3999562fe1039b44f0fb9297623bda49271cb7b17d7fab4dc14299e0e5f13eb8f3711dbffc10bf7ffa68838f0585b'
        '51cc7077b9bf14507a8fa95523af7179097d3ca6ec22be356e9fc8e2547c8c5f5e5df6d0cc4c3bfab37319bd8d59e4ac947074dde277843645b171af47b3fcc9'
        '761938b9d05430a72ff1102671d963e44d647ddb63b9a6e78979f365c6cd1e98b6a3763a4b9667ca75fbf23ee3812b4f09838061e8ba101d89d6f4dbd1104dc0'
        'bc5e233c9c5b7f799a126d51d672ad510ff4f6f75a573ea8b8e994d6be07375c0b4997acef16dacad555a7f36907a361f6cc4076b97d66c4c567dc9e707bc37e'
        '71bd229c0ee32703e3fc44021939f2909adca148035e6bfac44f35cb68cd8e03c01b477bfb29fe05f568728f27bd5b6311a267338d05cdbd5680af0900324c08'
        'd3d582336519191f73c8cf3c7bbb0a8df8ecbb333d864a32ad4b263daaeb193f771aa4b9cbf00ab929b4296da6db31fd575bdb2b337148147a76e25459f703ad'
        '93be2ff64a3217f92b369c067121683083859c7e939535e55f11818dc346d4862a50faa371315ad28ab54c9778c749d7684e8a7d68a18f774be3c2fe7891bd62'
        '246a189a0002e755bbed91257c324d0f34bab724f38a31bad1d5eb8bc5b126ecb3a0af8f69a6d0f5f084930c670d2747942beabab0b684f7f66a13044dec394a'
        '6dbc174a3c3b89b86d92ae3b467bfe535c6125cef776492bf865b6adb9d5995c72255376cd44eb8085b09ceca522f11bbd305b7beff096eed11954a44084d676'
        '4063dff5926b998e4faa0d04e7260009159fc40323922d46f1de00ad8dea453947e79fc085ac7c1d23e23b6537abcb794af3f3c5e3b6c040a2332c41612bef94'
        '88dd4e6a53b948ddd5bdf9a567a116f70047cc6cf5fb695b72b9ab571641e9af52e386c6e0b442c9dd794de39d57b26891dc8bb83e4c92506547f395d340915b'
        '9fbf8cf2aaa18c5cccca24783f40503cf7b7c66731f65450cc312e8b29145c56c23d31d19063dccdf3790ec06480d773d7d64de1672f38b7a4740a8aa0fd4f7d'
        'abafa39e57cf04396b841833215aca427655dd3b56ebc260b8a57d6376360b31a4b1d4493da76ec4dc0129939ab9e23cada70dd6f49e647f02bce12c81f6451a'
        'e6eda6cf4831df11facb124ab80972ddffabc8e2a61f8180275c7a95a8f00917301e9b8912f2418138c9dabd91c979d5d5b5d0b2b4b8eae3891f9c1880a4c526'
        '3373939e76f1ddb788b45424533c2e7687bbacae840fb3e6b1d49034e18315297af66dddf1b13d4f42033608123929b78819f38cca6cbc6c5ecca09bc67ab69f'
        '80da2c341d8564a47bc460fcdaf9196ac3bb77f0f2ba56bd71089e80e7481728a3ccbdcfcbc3bf70a9c9e5d9d9b01f2ca6615b67c7ab61003808ce00f6545ba3'
        'b8a64accada87ee5be989c5307805610c9b5c0327bc107aab237ac3225dd9e4c51b6c79a2a7de15fe187d3c32d7cbe1c462f9b0e9fb5d5a55a74236c7061e96e'
        '85aeb5920ee5879848be4057324153a077fe907bed527ed8f9b80a3c5ee1ef64786f63ee2999f5ba74e80a43e99ded3280ce27759c1f7b73259a6e2b5e584aa8'
        '58a94409205f7b670ab5745b8cbc234a38efd6a6217cef4efb7e397f091092e3e0c7790706b0a42accaa83d7509b8e244a98b9f0ba78349ee85f3164745c3501'
        '651de880cefd51665d854414c451cc80a33ed8f34e7559a95514abd81a2f58348c37dd75f272468eefd56562ba8c99093a6dd9af3ea57796a9db15164a40eda3'
        '2cdcf9ab03eb92f384caf1a2d90f82c75f880cb6286811e83217c883e421c116e7844ca193a010dc35e12eec46ede3663171a2f45f660ef5a8be95c474f61bfc'
        'f830baa8e9d2f2d844520ef3199a7ac62913afb016d40028d99865ba5c6143c08aa8cec9322a67d808fa526954a78416c90cf35ef31cc8dc4dec64950f58adfd'
        'eb1fb44a8d27b731a966fbc72c3692065102896bdb2d074c99b0f7327119fc88ff31848f42913a30631b65c4741dbd5f62aac88ada56ba4c36c24f34d7063072'
        '032c426a0e3a9d8282f5ce9ce4952bef051e2dedb0e56f90d9e18ccc32ea86acec84e42bcff695888f133a48b48418c59ea985dc9c5b179ca13cf9de44004618'
        '7cae5e42b6e16f3c4bf64dca3c7573c1b552424ff70bb6da0a21f121b53b2546b239c87953a090cd90f46a1c3c124e2fe19c560b1830b11334f8e64c92fb614d'
        '9b55cdad86ddd8c941c89802f13149e85d690a631ff3bf108bc7c06358f24598e66651170bcf675b80dbf680cfe6c15a14323eb3db14a7d4ee786051cc5c2a4c'
        '4c178d330117886848d232372a25ecf5cac46ad48a6fed580957d295eb1c4266836f4f807593d381f9089b2078c4185ba972f697ab353a850ebf35b6f140a4ac'
        '77bfba77f3548d267dc8142125bf26608c723bbdb2834317b3ea031ac64d9ff49bb4d75e29e2c759c03a662955697576d1c93153e9fb3e5dee86466bc29c78e1'
        '74a51f04237fba3caa25b2e0d49659f2e8330ce82288de866943d06b53690f31d48a77a4dd2e57db1f435b715fbca792268f2e191ffb59e57170d327ed41ac0a'
        '4a1724784d6b4f113e8c1954d399d07adc941a2e992e1c95ab38dbc5c31940e90ff4cec51d22da3bf971880817b4356e473747303146c2ab1be55ee4565aca41'
        '209387731490549d7b3d546ab149cea22e0ea1291356884f358cd87ca7d5425ca9a72f6f2cb7af46956634ffdb1a61d1ebfbfdbb5a2fc9fdc26d29acdc2ab0c0'
        '0661d98d1a106c736f5e23da60e81354786569d5e2124d1247297eac8ae95ae7f9971b5c80063ef7569eb7288da1ed012e8f0301e82400dff2c3c93cdbd93999'
        'a357104e814cde6669ab0b76d8d869ddd7fb03cf38bf1b32993780a31ac07e50cfc5d1af3e87d969ca3f9650ea3aefba3c55bf626c4c40502205a130a86c25a5'
        'e1d03f68918d03f980f4c2dd966e3788afe63f14e2d18dbd4dab2cdbfa1253e4823c0f5daa3a579e47319a3c2af35bc5af0a390e2ba91fe7621f6db8b1a60994'
        'f428818d1d4df4e46ec844458cfd5f9eef5d19a89778837502eb74ed6d421113ae9a9bc2fd4fb2bcf41d433635c34912e90b90a8993e92164e6a1efe0ebae82f'
        'b41ce5db19de2f4a5857debe31560b7b8216412e5df795032363839429f732b2d2359b3679a795c55a997913588f7d495c300df402529317ef2d03de24a74273'
        '06c5652eb2c70b8aba6d788415089b740c3510cd9c570838f656202ba2dc65d4f3289f6695413665de930e84fe287ef035ed8e83a0610a5a316e76a17442683a'
        '92cde696eec00e6758b58e73e8bc60ad1a73bb2a18d4fdfd24a19b5be715305a047943a02d94a9703c101ca0c769dbeb816f1f28809345bae0fec42fbc27bb34'
        '9fb6d2945184347e5b4f56f022d9b1b40559c1210edd91cb984d2c69e711dd297eab2a06d1e7d4008052fad658a9574ebd933083e7f8f3b3600b271593cbde15'
        'ce82294e480ad42f0001c799fd8131b60024b6097653f3c57564c75e54596616e376f0d7f1cf4e54d8c302a61ef164b4323f795bfa19b2c13ab9e927d37f1600'
        'd006a51f306a1397c14111788a23029a894e223a196649cac476acab761479db543bf4537ed5a2f4173ec94af04874b521a1d598ed8e98406cc2cf526d8e0083'
        '0cb9f39fd0b87e40bbce50ec7e834803bd0d28ff3c5ad25d2542498cfc5b625e7fc20880e34d325e05c51f411cf91721fe6b5a03565686be6cd6fe88772f80d0'
        'f25f01c5b27dced202fe76c1717b9eaec65dfa5f28db1910529f60f5ec21cc89c1a15df26c2dd09066a0d89e3f7d87c790e7886c3c2f0978a25f5ec7d1236099'
        'e3302d903d053f25aa666d572f74a8bbd3b65dde40eedcbf46e537ceb2294ac22b3772087fce04c4a780c2f18e855179c6ddc8af12d72a89b82957ce09deb52f'
        '4bd44cbe85c53902b8a360509703e3d38e8a5da75dd2c534a77f03ce6440632f6c83c92939069c60473c88ffb3abab0fbf11e39271f44f813b9f6432ea5f9a6b'
        'f115314dd2bb1da07bba7a90fec5c3acb7ccb5145efaea03d6806942e24d402c9a144a2fd07b82e727a0b79dedd4bdd87de0bbaf0944236563164fb6f117965e'
        'fbe96133bb6aedadc8e846c2495cda5c06b9cc76663e06b236a7721ede96798207f857ae8e0d4b672166ef7e16f024bba14422fb5481fd132ada7117e52fffb5'
        'd30bc1b6193e7ed024a34b9e0b6fee5995e6e05a070d42746f785c82d941fbf0a7925aad7ae27cb8a9c32c23640b85510b951b1b23cd20ac8f01f5fddb70edd8'
        'a56efdaae0344726debf5b74846edce8df7aa2357fbc7a05a3d369d1f457b02934a0d0ce2330072e03f1ac901e06e333c9393f795c761f8440307e7649ed5596'
        'f032ed44a6bc7f5b8dd7a545706c7733c4043ded755c12c622314c3b1f206363d27358f2d765a774f6f32abbdd8c31994b1e075c5307dcf65fc4e7a77081a5c7'
        'b9309da09b165fb57e83f84e3584d2479bd3336ed86e181e5df2d27daa92bd55d03d7f3fc226f03696af5f0f32d8e0e7ecd26ae7e50eed0200d0b0feaad07efb')

prepare() {
  cd "${_pkgname}-${_pkgver}"
  sed \
    -e 's/-Werror//' \
    -e 's/ncursesw5-config/ncursesw6-config/' \
    -e 's/shell git/shell false/' \
    -i Makefile

  # Disable default optimizations
  sed \
    -e 's/-Os/-O3/' \
    -e 's/-O0/-O3/' \
    -e 's/-Og/-O3/' \
    -e 's/CXXFLAGS += -ffast-math/#CXXFLAGS += -ffast-math/' \
    -i Makefile

  # Remove non-existent flags generating warnings
  sed \
    -e 's/-Wzero-as-null-pointer-constant \\/-Wzero-as-null-pointer-constant/' \
    -e 's/-Wno-range-loop-analysis/#-Wno-range-loop-analysis/' \
    -e 's/-Wno-unknown-warning-option/#-Wno-unknown-warning-option/' \
    -i Makefile

  # Fix filenames and paths
  sed -i 's|cataclysm-dda|cataclysm-bn|' CMakeLists.txt
  sed -i 's|TARGET_NAME = cataclysm|TARGET_NAME = cataclysm-bn|' Makefile
  sed -i 's|cataclysm.a|cataclysm-bn.a|' Makefile
  sed -i 's|cataclysm.a|cataclysm-bn.a|' tests/Makefile
  sed -i 's|cataclysm-dda|cataclysm-bn|' src/path_info.cpp

  # Fix version
  sed -i 's|VERSION = unstable|VERSION = "0.2-experimental 2023-04-03-2237"|' Makefile


  # # # Hotfixes
  #echo "Applying hotfixes"


  # # # Reverts
  echo "Applying revert patches"
  # Needless item removal
  patch -NREp1 --no-backup-if-mismatch -i "$srcdir"/revert-11_Obsoletion-and-removal-of-useless-bathroom-fluff-247.patch

  # Still more ammo patches to revert
  patch -NREp1 --no-backup-if-mismatch -i "$srcdir"/revert-10_still-another-ammo-patch-to-undo.patch

  # Revert yet more ammo rebalancing
  patch -NREp1 --no-backup-if-mismatch -i "$srcdir"/revert-09_undo-yet-more-ammo-balancing.patch

  # Revert balance pass of rifle ammunition.
  patch -NREp1 --no-backup-if-mismatch -i "$srcdir"/revert-08_undo-rifle-balance-pass.patch

  # Revert removal of reloaded ammunition.
  patch -NREp1 --no-backup-if-mismatch -i "$srcdir"/revert-07_Remove-handload-quality-distinction-1481.patch

  # Revert Hub 01 basement removal.
  patch -NREp1 --no-backup-if-mismatch -i "$srcdir"/revert-06_Obsolete-useless-hub01-basement-1457.patch
  
  # Revert the book changes for now.
  patch -NREp1 --no-backup-if-mismatch -i "$srcdir"/revert-02_revert-book-revamp.patch

  # Revert generic night vision.
  patch -NRp1 --no-backup-if-mismatch -i "$srcdir"/revert-03_generic-nv.patch

  # Revert telescopic lenses.
  patch -NRp1 --no-backup-if-mismatch -i "$srcdir"/revert-04_telescopic-lenses.patch

  # Revert the Infection Immune Trait and Revert Infection Resistant to as before. Also keep Truthteller.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/revert-01_removed-traits.patch


  # # # Various fixes for bugs I came across
  # # Ammo fixes
  echo "Applying ammo fixes"
  # Fix mulitple inconsistent ammunition names and handloaded status.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/ammo-01_inconsistent-ammo-names.patch

  # Set a fixed loudness for 20x66mm shotgun shells like that of other shotguns:
  # Other shotguns have fixed loudness to work around how the short range factors causes them to be far quieter than one would otherwise expect.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/ammo-02_fix-20x66mm-loudness.patch

  # Change reloaded_50bmg to be based on 50bmg:
  # The id and description make it pretty clear that reloaded_50bmg is not supposed to be based on Match rounds.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/ammo-03_fix-reloaded-50bmg.patch

  # Fix .22 casings not stacking when every other casing stacks.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/ammo-05_22-casings-can-stack.patch

  # Fix black powder scrap shot not being flagged as black powder.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/ammo-06_fix-bp-scrap-not-being-bp.patch

  # Fix ammo ordering so as to not prevent those items being modded:
  # Having copy-from items occuring earlier in a json than the item being copied from prevents items based on it being modified.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/ammo-10_ammo-order-fix.patch

  # Fix 40mm rounds volume.
  # Changing abstracts with mods does not seem to work, so here this is.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/ammo-11_fix-volume-40mm.patch


  # # armor fixes
  echo "Applying armor fixes"
  # Fix Ankle Ammo Pouch to not look like a backpack:
  # SDG added a tile for ammo pouches to bypass this bug, but this fix still makes sense.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/armor-01_ankle-ammo-pouch-is-not-a-backpack.patch

  # Fix fingerless survivor gloves losing base warmth:
  # They lose warmth already from the lack of coverage, no need to double up.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/armor-02_fix-survivor-fingerless-gloves-warmth.patch


  # # bionics fixes
  echo "Applying bionic fixes"
  # Fix npc not being able to install some additional CBMs:
  #  ie, soporific inducer, gasoline fuel cell, enhanced hearing, surgical scalpels.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/bionics-01_npc-can-use-more-bionics.patch

  # Fix some CBMs having excessively high price_postapoc values:
  #  All other CBMs are fixed to 1000, so these now are too.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/bionics-02_fix-bionic-prices.patch


  # # faction fixes
  echo "Applying faction fixes"
  # Backport the factions.json updates from DDA
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/faction-01_more-factions.patch

  # Fix faction food supply being calculated at 288 calories per person instead of 2500.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/faction-03_fix-food-supply-calculations.patch


  # # faction camp fixes
  echo "Applying faction camp fixes"
  # cur_level is set to -1 on all modern basecamps. Remove the recruiting penalty this legacy variable inadvertently induces.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/factioncamp-01_remove-legacy-recruiting-penalty.patch


  # # food fixes
  echo "Applying food fixes"
  # Fix several foods not being marked as the correct material:
  # This prevents odd outcomes such as carnivores drinking almond/soy milk and eating peanut butter.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/foods-01_fix-food-materials.patch

  # Fix several foods using unclear naming:
  # Rename can_corn from corn to canned corn to make its limited use in recipes more clear.
  # Fix pluralization of canned beans to also be canned beans.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/foods-02_fix-food-naming.patch

  # Fix several mutant components lacking the BAD_TASTE flag:
  # If raw mutant meat is flagged as disgusting, raw mutant fat must be just awful.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/foods-03_fix-mutant-bad-taste.patch

  # Allow canned corn to be used as a veggy_any requirement:
  # Canned corn was pretty much useless beyond making fish soup despite being a perfectly fine cooked vegetable.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/foods-04_allow-canned-corn-as-veggy.patch


  # # itemgroups fixes
  echo "Applying itemgroup fixes"
  # Stop police and SWAT carrying 4.6mm magazines despite having no compatible weapons:
  # The H&K UCP was removed from the base game some time ago.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/itemgroups-01_hk46-is-milspec.patch

  # Fix the pepperjack beef and burrito bowl MREs never dropping:
  # They weren't in the itemgroups for MREs or soldier class.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/itemgroups-02_add-missing-mre.patch

  # Fix items in unlooted, unused lockers and cabinets missing batteries:
  # They need to be marked as the battery contained inside the item.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/itemgroups-03_fix-shelter-batteries.patch


  # # medicine fixes
  echo "Applying medicine fixes"
  # Add -4 health to antibiotics:
  # weak are -2, strong are -10, this feels like a nice middle ground.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/meds-01_antibiotics-unhealthy.patch


  # # missions fixes
  echo "Applying migration fixes"
  # Remove UCP from migration list:
  # I can hack around this in my mod, but better to remove it here.
  # It has been gone so long, no save old enough is likely to even load.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/migration-01_remove-ucp.patch


  # # missions fixes
  echo "Applying mission fixes"
  # Fix Typos:
  # Foraging encounter has inconsistent monster references. Change all to cougar.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/mission-01_typos.patch


  # # monster fixes
  echo "Applying monster fixes"
  # Prefix medical zombies with "zombie" like other zombies:
  # It just felt weird seeing "nurse" in the enemy list.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/monsters-01_medical-zombies-called-zombies.patch


  # # mutation fixes
  echo "Applying mutation fixes"
  # Light Step feels too powerful in Bright Nights.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/mutations-01_nerf-lightstep.patch

  # Fix Evacuee 3 background 3 being player visible:
  # It was missing "player_display": false
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/mutations-02_fix-evac3-background-visible.patch

  # Port in DDA's eye colours
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/mutations-03_eye-colours.patch


  # # npc fixes
  echo "Applying NPC fixes"
  # Port the updates to Isherwood Farm from DDA
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-01_isherwood-update.patch

  # Port the updates to Tacoma Commune from DDA
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-02_tacoma-update.patch

  # Port the updates to New England Church Community from DDA
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-03_godco-update.patch

  # Port the updates to prison and island prison from DDA
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-04_island-prison-update.patch

  # Port the updates to kindred from DDA
  patch -NEp1 --no-backup-if-mismatch -i "$srcdir"/npc-05_kindred-update.patch

  # Port the updates to Mr Lapin from DDA
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-06_lapin-update.patch

  # Port the lighthouse family from DDA
  # Hack in some effects to use as timers and probe NPC mechanic skill.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-07_lighthouse-family_v2.patch

  # Update the Tacoma Nurse to buy almost every non-dangerous, non-electrical, and non-expensive medicine.
  # Also remove acceptance for various tools that are not correctly taken, such as first aid kits.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-08_nurse-takes-more-meds.patch

  # Update the FMC broker to buy most preserved foods.
  # Also update the dialogue to specify that he buys more types.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-09_broker-takes-more-foods.patch

  # Port the bunker merchant from DDA
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-10_bunker-merchant.patch

  # Fix npcs failing to reload activated gas masks:
  # Most masks lacked a "charges_per_use: 1" field, required for npcs to know they can reload it.
  # They still won't activate a fresh mask on their own though. :/
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-11_npcs-reload-gas-mask.patch

  # Reduce Eddie Isherwood mission from requiring 1000 clay down to 100:
  # 1000 units of clay is such an enormous amount compared to the previous 100 sand,
  # I can only reason it is a typo.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-12_fix-eddie-requiring-1000-clay.patch

  # Assorted typos in NPC dialogue.
  # Fix Jack Isherwood mission listing 10 jars, when it is actually 20.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/npc-20_dialogue-fixes.patch


  # # recipe fixes
  echo "Applying recipe fixes"
  # Fix reloaded 45-70 rounds and reloaded dragon shot not allowing dismantling when every other non-caseless round does.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/recipes-01_4570-dragon-can-be-dismantled.patch


  # # terrain and overmap fixes
  echo "Applying terrain and overmap fixes"
  # Fix some doors being unusable by npcs (incorrect door flag):
  # The DOOR flag is for terrain that can be opened, not those already open.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-02_fix-doors-for-npcs.patch

  # Fix missing floor in the tacoma clinic:
  # The hospital is still a mess. :/
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-03_tacoma-clinic-add-missing-floor.patch

  # Fix lumbermill gasoline being spilled instead of being inside the gas pump:
  # The gas pump was placed on top of a tile that didn't allow items inside, causing the gasoline to be shunted to the next valid one.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-04_lumbermill-gasoline-not-spilled.patch

  # Fix community garden liquid fertilizer being in a pit instead of in the storage tanks:
  # I'm pretty sure that having it all dumped in a pit was not intentional.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-05_community-garden-fertilizer-not-spilled.patch

  # Re-hide something that feels like spoilers.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-07_rehide-redacted.patch

  # Fix npcs unable to drink from firestation and shelter basecamps wells:
  # They were missing the water_well blueprint_provides.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-09_make-firestation-shelter-wells-npc-drinkable.patch

  # Fix military base minefield entrance rotation:
  # Both sides use the same tile, but it was incorrectly rotated 180 degrees. Fixed to 270 degrees.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-10_fix-milbase_minefield.patch

  # Fix up several typos, missing symbols, odd naming, and many extras lacking map notes support in map extras:
  # More choice is better than less. You can disable undesired map notes in the map notes settings menu.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-11_clean-up-map-extras.patch

  # Add missing stairs to the free merchant center:
  # The roof has stairs down, but the main floor lacked a matching stairs up.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/terrain-12_add_fmc_stairs.patch


  # # tool fixes
  echo "Applying tool fixes"
  # Mark the foldable plastic bottle and steel water bottle as containers:
  # Being counted as tools didn't seem to fit their role.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/tools-01_foldable-bottle-is-container.patch

  # Fix blood draw kit being categorized as a weapon:
  # Upstream changed item templates, so this sets it back to be a tool.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/tools-02_vacutainer-is-not-a-weapon.patch

  # Fix electric shears not using batteries nor charging via UPS:
  # Item was unusable without this patch.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/tools-03_shears-use-light-battery.patch

  # Normalize the manhack volumes to that of the base grenade/explosive:
  # I don't see how a c-4 manhack could be 1/4 the volume of a stick of c-4.
  # Grenade hacks were also thrice as big as the base grenade.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/tools-04_normalize-drone-volume.patch


  # # vehicle fixes
  echo "Applying vehicle fixes"
  # Replace the portable generator twin engine with a large 1 cylinder:
  # This way it can actually function as is.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/vehicles-01_portable-generator-engine.patch

  # Rename the FBI Car:
  # The stock name was clearly a typo of some sort.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/vehicles-02_fix-fbi-car-name.patch

  # Fix the black box to actually be installable:
  # No tool provided screwing 3 and wrenching 3.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/vehicles-03_black-box-can-be-installed.patch


  # # weapon fixes
  echo "Applying weapon fixes"
  # Fix the V29 pistol to copy-from pistol_energy:
  # This class seems entirely made for this weapon, but it was not flagged to use it.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/weapon-01_fix-v29-copy-from.patch

  # Fix the USP45 handgun not being modifiable:
  # It uses copy-from usp_9mm that loads later, which prevented modifying it.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/weapon-02_Fix-usp45-load-order.patch


  # # Uncategorized for now
  echo "Applying uncategorized fixes"
  # Fix rubber items dismantling into 10x item volume of rubber.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/etc-01_fix-rubbersplosion.patch

  # Add price_postapoc to a number of items that did not have one set.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/etc-02_add-missing-price-postapoc.patch

  # Convert a number of items to abstracts:
  # From the usage, these are intended to be abstracts but have not yet been converted from legacy items.
  # This fixes some erroneous weapon listings in custom martial arts.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/etc-03_fix-abstracts.patch


  # # # Various other fixes for bugs I came across that modify src
  echo "Applying source code fixes"
  # Fix radio, e-ink reader music, tactical tonfa not working with UPS.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_radio-can-use-ups.patch

  # Fix ammo loudness mulitplying by six instead of two.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_ammo-loudness-ap-times-2.patch

  # Fix smoker racks not accepting bionic firestarter.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_allow-bio-firestarter-on-smoker.patch

  # Fix Non-Player facton NPCs from becoming sleep deprived.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_stop-non-faction-npc-sleep-depirvation.patch

  # Fix Non-Player facton NPCs from becoming malnourished.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_stop-non-faction-npc-malnourishment.patch

  # Fix NPCs preferring tables to cots or woodstoves to the floor.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_stop-sleeping-on-tables.patch

  # Allow the hacker_laptop to utilize the extra functions.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_allow-hacker-laptop.patch

  # Expand the overmap tiles for the miltiary base to be less MMMM
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_more-military-base-overmap.patch

  # Allow npcs to pull food from the camp larder at the full range of tiles camp actions can be assigned from:
  # Should allow bases larger than 3x3 to have less food micromanagment for NPCs.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_npc-eat-from-further-camp.patch

  # Revert removal of half calorie consumption while sleeping:
  # Managing the food supply of more than a few NPCs in BN is extremely difficult compared to DDA.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/jc_reduced-kcal-during-sleep.patch


  # # # Additional changes
  echo "Applying vampirism patch"
  # Add vampire mutation lines and modify a number of functions to facilitate these traits.
  patch -Np1 --no-backup-if-mismatch -i "$srcdir"/vampirism.patch
}

build() {
  cd "${_pkgname}-${_pkgver}"

  #export CFLAGS="$CFLAGS -fPIE"
  export CXXFLAGS="$CXXFLAGS -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

  # Prevent segfaults when examine tile->search returns no results.
  #export CXXFLAGS="$(echo $CXXFLAGS | sed -i 's/-Wp,-D_GLIBCXX_ASSERTIONS//' - )" # No longer works
  export CXXFLAGS="$(echo $CXXFLAGS | sed 's/-Wp,-D_GLIBCXX_ASSERTIONS//')"
  #echo $CXXFLAGS

  make PREFIX=/usr RELEASE=1 USE_XDG_DIR=1 BACKTRACE=0 LOCALIZE=1 LANGUAGES=all RUNTESTS=0 VERBOSE=1 PCH=0 CCACHE=0
  make PREFIX=/usr RELEASE=1 USE_XDG_DIR=1 BACKTRACE=0 LOCALIZE=1 LANGUAGES=all RUNTESTS=0 VERBOSE=1 PCH=0 CCACHE=0 TILES=1 SOUND=1
  ./lang/compile_mo.sh
}

package_cataclysm-bn() {
  cd "${_pkgname}-${_pkgver}"

  make DESTDIR="$pkgdir" PREFIX="/usr" RELEASE=1 USE_HOME_DIR=1 LOCALIZE=1 LANGUAGES=all RUNTESTS=0 VERBOSE=1 PCH=0 CCACHE=0 install

  # Docs
  install -d "$pkgdir/usr/share/doc/cataclysm-bn"
  cp --reflink -r doc/* "$pkgdir/usr/share/doc/cataclysm-bn"
  # undo symlink
  rm "$pkgdir/usr/share/doc/cataclysm-bn/JSON_LOADING_ORDER.md"
  cp --reflink 'data/json/LOADING_ORDER.md' "$pkgdir/usr/share/doc/cataclysm-bn/JSON_LOADING_ORDER.md"

  # License
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # Languages
  cd lang/mo
  for i in *; do
    install -d "${pkgdir}/usr/share/locale/${i}/LC_MESSAGES"
    cp --reflink "${i}/LC_MESSAGES/cataclysm-bn.mo" "${pkgdir}/usr/share/locale/${i}/LC_MESSAGES"
  done

  # Help
  cd ./../..
  cp -r --reflink --no-preserve=ownership "./data/help" "${pkgdir}/usr/share/${pkgname}/"

#  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}

package_cataclysm-bn-tiles() {
  pkgdesc="A graphical post-apocalyptic roguelike."
  depends=('cataclysm-bn' 'sdl2_image' 'sdl2_ttf' 'freetype2' 'sdl2_mixer')
  cd "${_pkgname}-${_pkgver}"

  make DESTDIR="$pkgdir" PREFIX="/usr" RELEASE=1 LOCALIZE=1 LANGUAGES=all RUNTESTS=0 VERBOSE=1 PCH=0 CCACHE=0 TILES=1 SOUND=1 install


  # Icon
  #install -D 'data/osx/AppIcon.iconset/icon_128x128.png' "$pkgdir/usr/share/icons/hicolor/128x128/apps/$pkgname.png"
  #install -D 'data/osx/AppIcon.iconset/icon_128x128.png' "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -D "${srcdir}/icon_128x128.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/$pkgname.png"
  install -D "${srcdir}/icon_128x128.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -Dm644 "${srcdir}/$pkgname.desktop" "${pkgdir}/usr/share/applications/$pkgname.desktop"

  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"


  # Tileset
  mv "$srcdir/cataclysm-dda-tileset_undeadpeople-master" "$srcdir/undeadpeople"
  cp --reflink -r "$srcdir/undeadpeople" "$pkgdir/usr/share/cataclysm-bn/gfx"
  rm -rf "$pkgdir/usr/share/cataclysm-bn/gfx/MSX++UnDeadPeopleEdition"

  #mv "$srcdir/cataclysm-dda-mod_battle-maid-redone-tileset-master" "$srcdir/battle-maid-redone-tileset"
  cp --reflink -r "$srcdir/cataclysm-dda-mod_battle-maid-redone-tileset-master/battle-maid-redone-tileset-pt1" "$pkgdir/usr/share/cataclysm-bn/mods"
  cp --reflink -r "$srcdir/cataclysm-dda-mod_battle-maid-redone-tileset-master/battle-maid-redone-tileset-pt2" "$pkgdir/usr/share/cataclysm-bn/mods"


  # Sound
  mv "$srcdir/cataclysm-dda-soundpack_jcsoundpack-master" "$srcdir/jcsoundpack"
  cp --reflink -r "$srcdir/jcsoundpack" "$pkgdir/usr/share/cataclysm-bn/sound"

  # Music
  mv "$srcdir/cataclysm-dda-musicpack_coag-musicpack-master" "$srcdir/coag-musicpack"
  install -Dm644 "$srcdir/coag-musicpack/musicset.json" "$pkgdir/usr/share/cataclysm-bn/sound/jcsoundpack/musicset.json"
  cp --reflink -r "$srcdir/coag-musicpack/music" "$pkgdir/usr/share/cataclysm-bn/sound/jcsoundpack"


  # hack: remove overlapping files
  cd "$pkgdir/../cataclysm-bn"
  find . -type f -exec rm -f "$pkgdir"/{} \;
  cd "$pkgdir"
  find . -type d -empty -delete
}