# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: Partha Chowdhury <kira.laucas@gmail.com>

pkgname=conky
pkgver=1.11.0
pkgrel=2
pkgdesc='Lightweight system monitor for X'
url='https://github.com/brndnmtthws/conky'
license=('BSD' 'GPL')
arch=('x86_64')
makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db')
depends=('glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft'
         'imlib2' 'libxml2' 'alsa-lib')
source=($pkgname-${pkgver}.tar.gz::https://github.com/brndnmtthws/conky/archive/v${pkgver}.tar.gz
        https://github.com/brndnmtthws/conky/commit/4d098b053690861992f9daa4e3195b31295c735c.patch)
sha256sums=('cc75b5f6cdeefa83082f3dedf5a12105569c2cdc0ae3e7728922d79bc4abcf51'
            'c509b4a082ff84b5d3f7f002d737ab9f5941ac4564779b97307087ba663b8aaf')

options=('!strip' 'debug')
prepare() {
 cd "${srcdir}/${pkgname}-${pkgver}"
 patch -p1 -i ../4d098b053690861992f9daa4e3195b31295c735c.patch
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	cmake \
		-D CMAKE_BUILD_TYPE=Release \
		-D MAINTAINER_MODE=ON \
		\
		-D BUILD_CURL=OFF \
        -D BUILD_RSS=OFF \
		-D BUILD_WEATHER_METAR=OFF \
		-D BUILD_WEATHER_XOAP=OFF \
		-D BUILD_WLAN=ON \
		-D BUILD_EVE=OFF \
		-D BUILD_IMLIB2=ON \
		-D BUILD_APCUPSD=OFF \
		-D BUILD_MIXER_ALSA=ON \
		-D BUILD_PULSEAUDIO=OFF \
		-D BUILD_JOURNAL=OFF \
		\
		-D BUILD_XSHAPE=ON \
		-D BUILD_XDBE=ON \
		\
		-D BUILD_CMUS=OFF \
        -D BUILD_MPD=OFF \
        -D BUILD_MOC=OFF \
		-D CMAKE_INSTALL_PREFIX=/usr \
		.

	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
	install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm644 extras/vim/syntax/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/syntax/conkyrc.vim
	install -Dm644 extras/vim/ftdetect/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/ftdetect/conkyrc.vim
}