# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Alexander F Rødseth <xyproto@archlinux.org>
# Contriutor (Arch): Eric Belanger <eric@archlinux.org>
# Contributor (Arch): Jo Christian Bergskås <jcberg@gmail.com>

# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
# Arch version uses git

pkgname=fceux
pkgver=2.4.0
pkgrel=1
url='https://fceux.com/'
pkgdesc='Fast and ultra-compatible NES/Famicom emulator'
arch=(x86_64)
license=(GPL)
depends=(gd minizip qt5-base sdl2)
makedepends=(cmake glu mesa-libgl ninja)
source=("https://github.com/TASVideos/${pkgname}/archive/${pkgname}-${pkgver}.tar.gz")
b2sums=('23e8cb05db8ee56a57420d6c4be90e9f015f259e2a3b29b18d3de94f0b40aaeb8cbae60f64ceb422ab2f7795d3d03d3a659899cfc22dc61d6f903ff5866b7b42')

build() {
  cd ${pkgname}-${pkgname}-${pkgver}

  export CFLAGS="$CFLAGS -O3 -flto=auto -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -flto=auto -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

  mkdir -p build
  cd build

  cmake .. \
  -DCMAKE_INSTALL_PREFIX=/usr \
  -G Ninja
  ninja
}

package() {
  cd ${pkgname}-${pkgname}-${pkgver}
  DESTDIR="$pkgdir" ninja -C build install

  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r ${srcdir}/${pkgname}-${pkgname}-${pkgver}/documentation/* "${pkgdir}/usr/share/doc/${pkgname}/"
  install -Dm644 ${srcdir}/${pkgname}-${pkgname}-${pkgver}/changelog.txt "${pkgdir}/usr/share/doc/${pkgname}/"
}