# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>

# # I maintain this because:
# Arch version uses gtk
# Arch version uses http
# Arch version lacks additional optimization and hardening flags

_pkgname=freeciv
pkgname=freeciv-qt
pkgver=3.1.0
pkgrel=1
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64' 'aarch64')
url="http://www.freeciv.org/"
license=('GPL')
options=('lto')
depends=('qt6-base' 'sdl2_mixer' 'lua' 'sqlite' 'curl')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.xz)
sha512sums=('5d3f8df3defc4737be718ed371b41048f0cbdb25b83901009e4572b3910773a2bd33727bec0bc25169a3066b74152545c5bf813efeb5c9cf5429c85a20ccf594')
b2sums=('7e3d016dfe64c0402cff882514ba18934960ea9ab7b1247b947c0bebcdd961b5c9f282301098bed6cb869a19b1d02427aa2912599584f5d496f00f1e9cdae18a')

build() {
  cd ${_pkgname}-${pkgver}
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-shared \
    --enable-sys-lua \
    --enable-client=qt \
    --enable-fcmp=qt \
    --enable-fcdb=sqlite3 \
    --enable-aimodules
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}