# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=freeciv-qt
pkgver=2.5.11
pkgrel=1
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64')
url="http://www.freeciv.org/"
license=('GPL')
depends=('qt5-base' 'sdl_mixer' 'lua52' 'sqlite' 'curl' 'libtool')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/freeciv/freeciv-${pkgver}.tar.bz2
        lua52_compat.patch)
sha256sums=('4c9c526952fe977cb4b302b8ccf75798fd066c6dde670f72f677fe4964259aad'
            '85aff8a154b44c3c337c549c3ab9204429eaa627835b18b74146e801dd99a71e')

prepare() {
  cd freeciv-${pkgver}
  patch -p1 -i "$srcdir"/lua52_compat.patch
  autoreconf -vi
}

build() {
  cd freeciv-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --enable-shared --enable-sys-lua \
    --enable-client=qt --enable-fcmp=qt --enable-fcdb=sqlite3 --enable-aimodules
  make
}

package() {
  cd freeciv-${pkgver}
  make DESTDIR="${pkgdir}" install
}