# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>

# # I maintain this because:
# Arch version uses gtk
# Arch version uses http
# Arch version lacks additional optimization and hardening flags

_pkgname=freeciv
pkgname=freeciv-qt
pkgver=3.0.9
pkgrel=2
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64' 'aarch64')
url="http://www.freeciv.org/"
license=('GPL')
options=('lto')
depends=('qt5-base' 'sdl2_mixer' 'lua53' 'sqlite' 'curl')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.xz)
sha512sums=('22aaf8bc9976ebd1b05874a15f5be2a7f3b452e9bed7ac68c18d2395d18ff82954979f093174ec72b1a5218f253019e52cb223a112513ab3488c01f83bb5ccbc')
b2sums=('cb72bee83daea1dd90f972f3aaf3866cf160a447b57a7a25d20f84e74ce6580a697c3b95070b165fe5f864d9997cd5e637006ab325adb31a3de1cbc7d2406cc3')

build() {
  cd ${_pkgname}-${pkgver}
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-shared \
    --enable-sys-lua \
    --enable-client=qt \
    --enable-fcmp=qt \
    --enable-fcdb=sqlite3 \
    --enable-aimodules
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}