# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>

# # I maintain this because:
# Arch version uses gtk
# Arch version uses http
# Arch version lacks additional optimization and hardening flags

_pkgname=freeciv
pkgname=freeciv-qt
pkgver=3.0.4
pkgrel=1
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64' 'aarch64')
url="http://www.freeciv.org/"
license=('GPL')
options=('lto')
depends=('qt5-base' 'sdl2_mixer' 'lua53' 'sqlite' 'curl')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.xz)
sha1sum=('6871031b2ba6b3d8b54ff09ed7b9e121b2267647')
b2sums=('c3587c96b90b1b4c109f67184d251d5b2738fa2a1516981dad114ddedbca99997d2e8a7d682e73625c71853a5319ef155a56db0282604728b906f9d2fbad2979')

build() {
  cd ${_pkgname}-${pkgver}
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-shared \
    --enable-sys-lua \
    --enable-client=qt \
    --enable-fcmp=qt \
    --enable-fcdb=sqlite3 \
    --enable-aimodules
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}