# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>

# # I maintain this because:
# Arch version uses gtk
# Arch version uses http
# Arch version lacks additional optimization and hardening flags

_pkgname=freeciv
pkgname=freeciv-qt
pkgver=3.0.10
pkgrel=1
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64' 'aarch64')
url="http://www.freeciv.org/"
license=('GPL')
options=('lto')
depends=('qt5-base' 'sdl2_mixer' 'lua53' 'sqlite' 'curl')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.xz)
sha512sums=('4082e94deeda8d9b90f04137d6e7dfd39ff7232225a910f47519a464db553891e42289c1d7738f9ee0d9a16db143669bf8c4c5ce9492a4455ccd99906c956192')
b2sums=('c529b2039e38070fef4758f4d316cfe952dcce4d4a773e70da22f2a3948f0506be493b4af20529d80749b47954bdd87a7aca8efb72c5502fefb2c103977f4e12')

build() {
  cd ${_pkgname}-${pkgver}
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-shared \
    --enable-sys-lua \
    --enable-client=qt \
    --enable-fcmp=qt \
    --enable-fcdb=sqlite3 \
    --enable-aimodules
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}