# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>

# # I maintain this because:
# Arch version uses gtk
# Arch version uses http
# Arch version lacks additional optimization and hardening flags

_pkgname=freeciv
pkgname=freeciv-qt
pkgver=3.0.7
pkgrel=1
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64' 'aarch64')
url="http://www.freeciv.org/"
license=('GPL')
options=('lto')
depends=('qt5-base' 'sdl2_mixer' 'lua53' 'sqlite' 'curl')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.xz)
sha512sums=('b78fc6880348a5b8a53977930b8f2516414aad5c65ebce2aef12000931ff15b2e6786c1d6883da9e9e09d039a18eb91463b17b6a9467908ab3c052ef7fe94bfb')
b2sums=('22fa03a09c6242259d8319ff413b08a88953f5ea169af8907b59c1e59c1f146b2dd18fa58b62d80862bc388b1d01384dc74c328cfa9e5c55d5080c75bbd9b3a4')

build() {
  cd ${_pkgname}-${pkgver}
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-shared \
    --enable-sys-lua \
    --enable-client=qt \
    --enable-fcmp=qt \
    --enable-fcdb=sqlite3 \
    --enable-aimodules
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}