# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): David A. Redick <david.a.redick@gmail.com>
# Contributor (AUR): Petteri Tolonen <petteri dot tolonen at gmail dot com>

# # I maintain this because:
# AUR version uses ftp

pkgname=freedink
pkgver=109.2
pkgrel=1
url='https://www.gnu.org/software/freedink/'
pkgdesc='Humorous top-down adventure and role-playing game.'
arch=('x86_64')
license=('GPL3')
depends=('freedink-data' 'libzip' 'bzip2' 'zlib' 'fontconfig' 'freetype2'
         'sdl_image' 'sdl_mixer' 'sdl_ttf' 'sdl_gfx' 'sdl' 'expat'
         'libutil-linux' 'libpng' 'harfbuzz' 'glib2' 'graphite' 'pcre')
makedepends=('automake' 'autoconf' 'check' 'help2man' 'make')
source=("https://ftp.gnu.org/gnu/freedink/${pkgname}-${pkgver}.tar.gz")
sha512sums=('222a5facbe1d40a86690b0c224e24651287718478c18f77deeebe0d5438cdea3f02a28dd18d9699c5eb098a8cceceabda6e8a2326ff58a6e968a89f86d9fd83f')

build () {
	cd "${srcdir}/${pkgname}-${pkgver}"
	./configure --prefix=/usr --disable-embedded-resources
	make
}

check () {
	cd "${srcdir}/${pkgname}-${pkgver}"

	# This is just a trivial check.
	make check

	# This for the packaging of the source code in a snap shot package
	# NOT the installed build artifacts.
	#make distcheck
}

package () {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
}