# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (AUR): Christian Krause ("wookietreiber") <christian.krause@mailbox.org>

# # I maintain this because:
# AUR version is unmaintained

pkgname=freeorion
pkgver=0.4.9
_exver=2020-02-02.db53471
pkgrel=1
pkgdesc="turn-based space empire and galactic conquest (4X) computer game"
url="http://www.freeorion.org/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('boost-libs' 'python2' 'sdl2' 'libvorbis' 'glew' 'openal' 'hicolor-icon-theme' 'freetype2')
makedepends=('boost' 'cmake')
conflicts=('freeorion-git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/freeorion/freeorion/releases/download/v$pkgver/FreeOrion_v${pkgver}_${_exver}_Source.tar.gz")
b2sums=('527e2eef94b2ae8c0c50a53d98abeb4fc799803a9cd091e932aaaef89e2371987f47dbbb9ff16baad478c0ca05da35aa148b6fd16026f44d3df3f296a513d7bc')

prepare() {
  cd "$srcdir"/src-tarball

  mkdir -p build
}

build() {
  cd "$srcdir"/src-tarball/build

  # PIE breaks compiling
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4"

  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_LIBDIR=lib \
    ..

  make
}

package() {
  cd "$srcdir"/src-tarball/build

  make DESTDIR="$pkgdir" install
}