# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer (Parabola): Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor (Parabola): Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>

# # I maintain this because:
# Parabola version out-of-date
# Change metadata to Artix

pkgname=gst-plugins-bad
pkgver=1.16.0
pkgrel=5.1
pkgdesc="GStreamer Multimedia Framework Bad Plugins"
pkgdesc+=", without nonfree faac support"
url="https://gstreamer.freedesktop.org/"
arch=(x86_64)
license=(LGPL)
depends=(mjpegtools gst-plugins-base-libs curl chromaprint libmms faad2 celt libdca libdvdnav
         libmodplug libgme wayland libofa openjpeg2 libwebp libsrtp gnutls sbc rtmpdump libgudev
         libexif libdvdread libvdpau libmpeg2 wildmidi ladspa openal libusb vulkan-icd-loader
         libfdk-aac soundtouch spandsp neon webrtc-audio-processing libdc1394 libmpcdec zvbi
         openexr libbs2b libnice lcms2 bluez-libs glu srt aom x265 liblrdf libde265 zbar
         gst-plugins-good)
makedepends=(python gtk-doc git gobject-introspection gtk3 vulkan-headers vulkan-validation-layers
             librsvg libtiger fluidsynth lilv meson)
_commit=5fde70bb63a1cbf6f734fb2429e74ffb53126217  # tags/1.16.0^0
source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad.git#commit=$_commit"
        'gst-common::git+https://gitlab.freedesktop.org/gstreamer/common.git')
sha256sums=('SKIP'
            'SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.common.url "$srcdir/gst-common"
  git submodule update
}

build() {
  arch-meson $pkgname build \
    -D directfb=disabled \
    -D faac=disabled \
    -D flite=disabled \
    -D gsm=disabled \
    -D iqa=disabled \
    -D msdk=disabled \
    -D nvdec=disabled \
    -D nvenc=disabled \
    -D opencv=disabled \
    -D openh264=disabled \
    -D openmpt=disabled \
    -D openni2=disabled \
    -D opensles=disabled \
    -D sctp=disabled \
    -D tinyalsa=disabled \
    -D voaacenc=disabled \
    -D voamrwbenc=disabled \
    -D wasapi=disabled \
    -D wpe=disabled \
    -D gobject-cast-checks=disabled \
    -D glib-asserts=disabled \
    -D glib-checks=disabled \
    -D package-name="GStreamer Bad Plugins (Artix Linux)" \
    -D package-origin="https://www.artixlinux.org/"
  ninja -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}