# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Thibaut Sautereau (thithib) <thibaut at sautereau dot fr>

# # I maintain this because:
# AUR version uses underscore
# I use it and it is not in an official repo

pkgname=hardened-malloc
_altname=hardened_malloc
pkgver=10
pkgrel=1
pkgdesc="Hardened allocator designed for modern systems"
arch=('x86_64' 'aarch64')
url="https://github.com/GrapheneOS/hardened_malloc"
license=('MIT')
depends=('gcc-libs')
makedepends=('git')
checkdepends=('python')
provides=('libhardened_malloc.so')
source=("git+https://github.com/GrapheneOS/${_altname}#tag=$pkgver?signed")
b2sums=('SKIP')
validpgpkeys=('65EEFE022108E2B708CBFCF7F9E712E59AF5F22A') # Daniel Micay <danielmicay@gmail.com>

build() {
  cd "${_altname}"

  make VARIANT=default
  make VARIANT=light
}

check() {
  cd "${_altname}"

  make CONFIG_WERROR=false test
}

package() {
  cd "${_altname}"

  install -Dm755 --target-directory="$pkgdir/usr/lib" \
    out/libhardened_malloc.so \
    out-light/libhardened_malloc-light.so
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}