# $Id$
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Maintainer: Bruno Pagani <archange@archlinux.org>

pkgname=keepassxc
pkgver=2.3.4
pkgrel=1
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=(GPL)
depends=(hicolor-icon-theme libgcrypt argon2 libxtst qt5-x11extras)
makedepends=(cmake qt5-tools)
source=("https://github.com/keepassxreboot/$pkgname/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"{,.sig})
sha256sums=('0c24a78895185b9b6b098f08a15b332c600f80aa570d608940fcc2a38e02780a'
            'SKIP')
validpgpkeys=('BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2') # KeePassXC Release <release@keepassxc.org>

prepare() {
	mkdir -p build
}

build() {
	cd build
	cmake ../$pkgname-$pkgver \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_INSTALL_LIBDIR=lib \
		-DWITH_XC_AUTOTYPE=ON       \
		-DWITH_XC_BROWSER=OFF       \
		-DWITH_XC_HTTP=OFF          \
		-DWITH_XC_YUBIKEY=OFF       \
		-DWITH_TESTS=ON             \
		-DWITH_GUI_TESTS=OFF        \
		-DWITH_DEV_BUILD=OFF        \
		-DWITH_ASAN=OFF             \
		-DWITH_COVERAGE=OFF
	make
}

check() {
	cd build
	make test
}

package() {
	cd build
	make DESTDIR="$pkgdir" install
}