# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer (Arch): Bruno Pagani <archange@archlinux.org>

# # I maintain this because:
# Arch version uses yubikey libs
# Arch version enables networking support
# Arch version lacks additional optimization and hardening flags

_NETBUILD=OFF

pkgname=keepassxc
pkgver=2.6.0
pkgrel=1
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=(GPL)
depends=(argon2 hicolor-icon-theme libgcrypt libsodium libxtst qrencode
         qt5-svg qt5-x11extras
         )
makedepends=(asciidoctor cmake qt5-tools)
optdepends=('xclip: keepassxc-cli clipboard support')
source=("$pkgname-$pkgver.tar.xz::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"
        "$pkgname-$pkgver.tar.xz.sig::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz.sig")
b2sums=('9872b9fa5f809e2d2e6ed4a233ca248d19ada1c495f4c8febdfa765565963a01a5ede97d1f3830a39a6dc1063f88cb77b9b216776767111686288284aae63399'
        'SKIP')
# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
              71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
              AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
              C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)

build() {

  # lto breaks compiling
  # PIE causes the tests to fail
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all"

  cmake -S $pkgname-$pkgver -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DWITH_XC_AUTOTYPE=ON \
    -DWITH_XC_NETWORKING=OFF \
    -DWITH_XC_BROWSER=${_NETBUILD} \
    -DWITH_XC_YUBIKEY=OFF \
    -DWITH_XC_SSHAGENT=OFF \
    -DWITH_XC_KEESHARE=OFF \
    -DWITH_XC_UPDATECHECK=OFF \
    -DWITH_XC_FDOSECRETS=OFF
    cmake --build build
}

check() {
  cmake --build build --target test
}

package() {
  cmake --build build --target install -- DESTDIR="$pkgdir"
}