# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer (Arch): Bruno Pagani <archange@archlinux.org>

# # I maintain this because:
# Arch version uses yubikey libs
# Arch version enables networking support
# Arch version enables update check
# Arch version lacks additional optimization and hardening flags

pkgname=keepassxc
pkgver=2.5.0
pkgrel=1
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=(GPL)
depends=(argon2 hicolor-icon-theme libgcrypt libsodium libxtst qrencode
         qt5-svg qt5-x11extras
         )
makedepends=(cmake qt5-tools)
source=("$pkgname-$pkgver.tar.xz::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"
        "$pkgname-$pkgver.tar.xz.sig::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz.sig")
sha256sums=('6359ce972b720a8bce1e8ba54000666e9c58f9164f2e9e52bef2e24e46127881'
            'SKIP')
validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2 # KeePassXC Release <release@keepassxc.org>
              3489040C1F0C3EEAB8D556A5440FC65F2E0C6E01 # Jonathan White <support@dmapps.us>
              B3724F5B2C98B5B0AEDDBD582AC0283D4CFC9A10) # Janek Bevendorff <janek@jbev.net>

prepare() {
	mkdir -p build
}

build() {
	cd build
  # lto breaks compiling
  # PIE cause the tests to fail
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all"

	cmake ../$pkgname-$pkgver \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_INSTALL_LIBDIR=lib \
		-DWITH_XC_AUTOTYPE=ON \
		-DWITH_XC_NETWORKING=OFF \
		-DWITH_XC_BROWSER=OFF \
		-DWITH_XC_YUBIKEY=OFF \
		-DWITH_XC_SSHAGENT=OFF \
		-DWITH_XC_KEESHARE=OFF \
		-DWITH_XC_UPDATECHECK=OFF \
		-DWITH_XC_FDOSECRETS=OFF
	make
}

check() {
	cd build
	make test
}

package() {
	cd build
	make DESTDIR="${pkgdir}" install
}