# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer (Arch): Bruno Pagani <archange@archlinux.org>

# # I maintain this because:
# Arch version uses yubikey libs
# Arch version enables networking support
# Arch version does not use ~/.config
# Arch version lacks additional optimization and hardening flags

_NETBUILD=OFF

pkgname=keepassxc
pkgver=2.7.7
pkgrel=2
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=('GPL-2.0-only OR GPL-3.0-only OR LGPL-2.1-only')
options=('!lto')
depends=(argon2 botan curl hicolor-icon-theme libxtst
         minizip pcsclite qrencode qt5-svg qt5-x11extras libusb)
makedepends=(asciidoctor cmake qt5-tools)
optdepends=('xclip: keepassxc-cli clipboard support under X server'
            'wl-clipboard: keepassxc-cli clipboard support under Wayland')
checkdepends=(xclip xorg-server-xvfb)
provides=(org.freedesktop.secrets)
source=(https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/keepassxc-$pkgver-src.tar.xz{,.sig})
sha256sums=('58fc45ae98e4b3ffb052103014f5b97a41fefd17102c7f56073934dd3a82ee67'
            'SKIP')
b2sums=('d94c42334bbfde46f14f4b14612f4297c500da76ba8a82de26c4a450ee1cacb9a15517a84ef445441651dc33a71f9ca7bca63bb04d0a4e8eeb0380eded6e5477'
        'SKIP')
# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
              71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
              AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
              C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)

prepare() {

  sed -i 's|Exec=keepassxc %f|Exec=keepassxc --localconfig ~/.config/keepassxc/keepassxc.ini %f|' $srcdir/$pkgname-$pkgver/share/linux/org.keepassxc.KeePassXC.desktop.in
}

build() {

  # PIE causes the tests to fail
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all"

  cmake -S keepassxc-$pkgver -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DWITH_XC_AUTOTYPE=ON \
    -DWITH_XC_NETWORKING=OFF \
    -DWITH_XC_BROWSER=${_NETBUILD} \
    -DWITH_XC_YUBIKEY=OFF \
    -DWITH_XC_SSHAGENT=OFF \
    -DWITH_XC_KEESHARE=OFF \
    -DWITH_XC_UPDATECHECK=OFF \
    -DWITH_XC_FDOSECRETS=OFF \
    -DWITH_TESTS=OFF # test hang indefinitely on 2.7.7
  cmake --build build
}

#check() {
#  xvfb-run --auto-servernum cmake --build build --target test
#}

package() {
  cmake --build build --target install -- DESTDIR="$pkgdir"
}