# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer (Arch): Bruno Pagani <archange@archlinux.org>

# # I maintain this because:
# Arch version uses yubikey libs
# Arch version enables networking support
# Arch version does not use ~/.config
# Arch version lacks additional optimization and hardening flags

_NETBUILD=OFF

pkgname=keepassxc
pkgver=2.7.9
pkgrel=4
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=('GPL-2.0-only OR GPL-3.0-only OR LGPL-2.1-only')
options=('!lto') # lto causes tests to fail, which means something is breaking
depends=(argon2 botan hicolor-icon-theme libxtst
         minizip pcsclite qrencode qt5-svg qt5-x11extras libusb)
makedepends=(asciidoctor cmake qt5-tools)
optdepends=('xclip: keepassxc-cli clipboard support under X server'
            'wl-clipboard: keepassxc-cli clipboard support under Wayland')
checkdepends=(xclip xorg-server-xvfb)
provides=(org.freedesktop.secrets)
source=(https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/keepassxc-$pkgver-src.tar.xz{,.sig})
sha256sums=('3c44e45f22c00ddac63d8bc11054b4b0ada0222ffac08d3ed70f196cb9ed46fd'
            'SKIP')
b2sums=('d9be3e577ae918160662558bb8bd724b5ca5982cb1bba5cda47f0dff042ea9a5c7393dd76ad195a7ba6c9b9e8371c4416840e4ff89e07c610d7351859586acfa'
        'SKIP')
# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
              71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
              AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
              C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)

prepare() {

  sed -i 's|Exec=keepassxc %f|Exec=keepassxc --localconfig ~/.config/keepassxc/keepassxc.ini %f|' $srcdir/$pkgname-$pkgver/share/linux/org.keepassxc.KeePassXC.desktop.in
}

build() {

  # Too many FORTIFY_SOURCE redefined warnings. Switch back to 2.
  export CFLAGS="${CFLAGS/_FORTIFY_SOURCE=3/_FORTIFY_SOURCE=2}"
  export CXXFLAGS="${CXXFLAGS/_FORTIFY_SOURCE=3/_FORTIFY_SOURCE=2}"

  # PIE causes the tests to fail
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all"

  cmake -S keepassxc-$pkgver -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DWITH_XC_AUTOTYPE=ON \
    -DWITH_XC_NETWORKING=OFF \
    -DWITH_XC_BROWSER=${_NETBUILD} \
    -DWITH_XC_YUBIKEY=OFF \
    -DWITH_XC_SSHAGENT=OFF \
    -DWITH_XC_KEESHARE=OFF \
    -DWITH_XC_UPDATECHECK=OFF \
    -DWITH_XC_FDOSECRETS=OFF \
    -DWITH_GUI_TESTS=ON \
    -DWITH_TESTS=ON
  cmake --build build
}

check() {
  xvfb-run --auto-servernum cmake --build build --target test
}

package() {
  cmake --build build --target install -- DESTDIR="$pkgdir"
}