# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor (AUR): C. Dominik Bódi <dominikdotbodiatgmxdotde>
# Contributor (AUR): Joe Davison <joe@warhaggis.com>

# # I maintain this because:
# AUR version uses http
# AUR version uses unofficial repo
# AUR version needlessly purges old build folder
# AUR version uses qt-webengine
# AUR version lacks additional optimization and hardening flags

pkgname=lgogdownloader
pkgver=3.17
pkgrel=1
pkgdesc="Open source downloader for GOG.com games, uses the GOG.com API"
url="https://github.com/Sude-/lgogdownloader"
arch=(x86_64 i686 pentium4)
license=('WTFPL')
options=(lto)
depends=('boost-libs' 'jsoncpp' 'tinyxml2' 'rhash' 'tidy' 'glibc' 'gcc-libs' 'curl')
depends+=('libboost_filesystem.so')
makedepends=('cmake' 'boost' 'help2man')
conflicts=('lgogdownloader-git')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/Sude-/lgogdownloader/archive/v${pkgver}.tar.gz)
b2sums=('a8f106abbcfbbe83c2618b2f0e5ceb5c687319720b86eb38283407af35abf6128360456945c56cc4dbc2afbfd4f923ca177c97ccd45e6aa3b57768e25967a6fb')

prepare() {
    mkdir $srcdir/${pkgname}-${pkgver}/build
}

build() {

  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

    cd $srcdir/${pkgname}-${pkgver}/build
    cmake .. \
            -DCMAKE_INSTALL_PREFIX=/usr \
            -DCMAKE_BUILD_TYPE=Release \
            -DUSE_QT_GUI=OFF
    make

}

package() {
    cd $srcdir/${pkgname}-${pkgver}/build
    
    make DESTDIR=${pkgdir} install
    install -Dm644 $srcdir/${pkgname}-${pkgver}/COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}