From 398d1a1319394e9f704fdd5d5fbcd85a5b6b7e68 Mon Sep 17 00:00:00 2001
From: jc_gargma <jc_gargma@iserlohn-fortress.net>
Date: Wed, 6 May 2020 23:33:20 -0700
Subject: Initial commit

---
 PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 PKGBUILD

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..c05bee8
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,56 @@
+# This package is based on libva-intel-driver just with the hybrid codec flag
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (AUR): DetMittens
+# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
+# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
+# Contributor (Arch): Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
+
+# # I maintain this because:
+# I use it and it is not in an official repo
+
+pkgname=libva-intel-driver-hybrid
+pkgver=2.4.0
+pkgrel=1
+pkgdesc='VA-API implementation for Intel G45 and HD Graphics family'
+arch=(x86_64)
+url=https://01.org/linuxmedia/vaapi
+license=(MIT)
+depends=(
+  libva
+  libdrm
+)
+makedepends=(
+  git
+  meson
+  xorgproto
+)
+replaces=(libva-driver-intel)
+optdepends=('intel-hybrid-codec-driver: Provides codecs with partial HW acceleration')
+conflicts=('libva-intel-driver')
+provides=('libva-intel-driver')
+source=(git+https://github.com/intel/intel-vaapi-driver.git#tag=d595d01d6421eae30824538fa6d150701ed077df)
+sha256sums=('SKIP')
+
+pkgver() {
+  cd intel-vaapi-driver
+
+  git describe --tags
+}
+
+prepare() {
+  cd intel-vaapi-driver
+
+  # Only relevant if intel-gpu-tools is installed,
+  # since then the shaders will be recompiled
+  sed -i '1s/python$/&2/' src/shaders/gpp.py
+}
+
+build() {
+  arch-meson -Denable_hybrid_codec=true intel-vaapi-driver build
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 intel-vaapi-driver/COPYING -t "${pkgdir}"/usr/share/licenses/libva-intel-driver
+}
-- 
cgit v1.2.1