# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Maintainer (Arch): Carl Smedstad <carsme@archlinux.org>
# Contributor (Arch): Eric Bélanger <eric@archlinux.org>

# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
# Arch version broken with arch-style lto

pkgname=lincity-ng
pkgver=2.11.2
pkgrel=1
pkgdesc="A city simulation game"
arch=('x86_64')
url="https://github.com/lincity-ng/lincity-ng"
license=(
  'CC-BY-SA-2.0'
  'GPL-2.0-or-later'
  'LicenseRef-ArevFontsCopyright'
  'LicenseRef-BitstreamVeraFontsCopyright'
)
depends=(
  'gcc-libs'
  'glibc'
  'hicolor-icon-theme'
  'libglvnd'
  'libxml2'
  'physfs'
  'sdl2'
  'sdl2_gfx'
  'sdl2_image'
  'sdl2_mixer'
  'sdl2_ttf'
  'zlib'
)
makedepends=(
  'cmake'
  'libxslt'
)
# # For some reason this breaks compiling. "error: C++ compiler cannot create executables"
# # But old-fashioned raw injection of -flto=auto via export doesn't.
options=(!lto)
source=(https://github.com/lincity-ng/lincity-ng/archive/$pkgname-$pkgver.tar.gz)
sha256sums=('4dd327c225168de86e730277fa9b0d9e859c64ca36933ea7cfe125225510e0e3')
b2sums=('9bafe367e97c599d7950af0f208c472ec937d53837d03776442b61f7a4f509ac368cf5f04ea3c170ad4a99e0166898a8a8d65b7bfe91508896e589e453739296')

build() {
  cd ${pkgname}-${pkgname}-${pkgver}

  export CFLAGS="$CFLAGS -O3 -fPIE -flto=auto"
  export CXXFLAGS="$CXXFLAGS -O3 -fPIE -flto=auto"
  export LDFLAGS="$LDFLAGS,-pie"
  
  cmake -S . -B build \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev
  cmake --build build
}

package() {
  cd ${pkgname}-${pkgname}-${pkgver}
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" COPYING-data.txt
  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" COPYING-fonts.txt
}