# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Olaf Bauer <hydro@freenet.de>

# # I maintain this because:
# AUR version uses http

pkgname=makemkv
pkgver=1.15.1
pkgrel=1
pkgdesc="DVD and Blu-ray to MKV converter and network streamer"
arch=('i686' 'x86_64')
url="https://www.makemkv.com"
license=('LGPL' 'MPL' 'custom')
depends=('qt5-base' 'libxkbcommon-x11' 'hicolor-icon-theme' 'icu' 'ffmpeg')
if [ "$CARCH" = "x86_64" ]; then
  optdepends=('lib32-glibc: dts support'
              'ccextractor: extract CC streams from some DVD media')
fi
install=makemkv.install
source=(https://www.makemkv.com/download/${pkgname}-bin-${pkgver}.tar.gz
        https://www.makemkv.com/download/${pkgname}-oss-${pkgver}.tar.gz
        makemkv.1
        makemkvcon.1
        mmdtsdec.1)
b2sums=('4eafd3dacfc27a5f855d4c8e620f191a0abfa4e6795992533ed75a82e8ca2cd490aafa52207da32774c9059b196b1bf834877f4c3e96b0a661b03c8c9226ad1a'
        'e0642c0c740b0817a0d347e4588691282cfae1f81e827431ecad7fcd64b4cfca687829b7646614833f2123216c304e2705b2ecaf9a30904735c6c3c0cc05a845'
        '92bac30ca1ca062bb235389ac9e558649c7efc31b7690a4540cae6f9f032843ce4ed74eb091bcfba1e24ad0fbc904963c7aed2d6761883800ef319a3ed074cd0'
        'a318361982271bee3db2fa6f3e2b51afd7fe35f3dcb821c24bc21f8189be74cf9093559dbf9689eedd458226b30ddf59333af10ef509dc850331639b9035be39'
        '2402c0338cf3a5e28c46af98a72c76e8e22d54e812f1d1f0dc156590657af15a6264a05a5fbcbf288fea09b5f4eb6fd1bb3e8672e9afc1615170b7bd83ba69b1')

build() {
  cd "${srcdir}/${pkgname}-oss-${pkgver}"
  CC=gcc CXX=g++ ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-oss-${pkgver}"
  make DESTDIR=\""${pkgdir}"\" install

  cd "${srcdir}/${pkgname}-bin-${pkgver}"
  install -d tmp
  echo accepted > tmp/eula_accepted
  make DESTDIR=\""${pkgdir}"\" install

  install -Dm 644 src/eula_en_linux.txt "${pkgdir}/usr/share/licenses/${pkgname}/eula_en_linux.txt"

  cd "${srcdir}/"
  install -d "${pkgdir}/usr/share/man/man1/"
  install -m 644 -t "${pkgdir}/usr/share/man/man1/" makemkv.1 makemkvcon.1 mmdtsdec.1
}