# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Trevor Bergeron <aur@sec.gd>

# # I maintain this because:
# AUR version uses http
# I use it and it is not in an official repo

pkgname=nginx-mainline-mod-rtmp
pkgver=1.2.2
pkgrel=16

_modname="nginx-rtmp-module"
_nginxver=1.25.5

pkgdesc="Module for mainline nginx that adds RTMP support"
arch=('aarch64' 'i686' 'x86_64')
depends=("nginx-mainline=${_nginxver}")
makedepends=("nginx-mainline-src=${_nginxver}")
url="https://github.com/arut/nginx-rtmp-module"
license=('BSD')

source=(${pkgname}-${pkgver}.tar.gz::https://github.com/arut/$_modname/archive/v$pkgver.tar.gz)
sha256sums=('07f19b7bffec5e357bb8820c63e5281debd45f5a2e6d46b1636d9202c3e09d78')
b2sums=('8745816b879f506720955d6c7e5e8af036e88b3601a680071ffb255a3ec31d69e132b5cc8b493202fa985eb30b8529428f683b5154a0054c0ee990d3185c7abf')

prepare() {
    mkdir -p build
    ln -sf /usr/src/nginx/auto build/
    ln -sf /usr/src/nginx/src build/
}

build() {
    cd build

    # Cribbed from aur/nginx-mainline-mod-http-xslt-filter by Sergey Shatunov
    opts=$(nginx -V 2>&1 | grep 'configure arguments' | sed -r 's@^[^:]+: @@')
    IFS=$'\n' opts=( $(xargs -n1 <<< "$opts") )
    /usr/src/nginx/configure "${opts[@]}" --add-dynamic-module=../$_modname-$pkgver

    make modules
}

package() {
    cd "$srcdir/build/objs"
    for mod in *.so; do
        install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
    done
}