# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Trevor Bergeron <aur@sec.gd>

# # I maintain this because:
# AUR version uses http
# I use it and it is not in an official repo

pkgname=nginx-mainline-mod-rtmp
pkgver=1.2.2
pkgrel=1.4

_modname="nginx-rtmp-module"
_nginxver=1.21.3

pkgdesc="Module for mainline nginx that adds RTMP support"
arch=('i686' 'x86_64')
depends=("nginx-mainline=${_nginxver}")
url="https://github.com/arut/nginx-rtmp-module"
license=('BSD')

source=(
    https://nginx.org/download/nginx-$_nginxver.tar.gz
    https://nginx.org/download/nginx-$_nginxver.tar.gz.asc
    ${pkgname}-${pkgver}.tar.gz::https://github.com/arut/$_modname/archive/v$pkgver.tar.gz
)
b2sums=('424e9525f8f27dad6a49e7ec7c76160331ce98015d1023c71e9c60146aef7d330c780dc69bf2db01da0bedce3acecb156b3e108c24d2683ffee2954396ff440e'
        'SKIP'
        '8745816b879f506720955d6c7e5e8af036e88b3601a680071ffb255a3ec31d69e132b5cc8b493202fa985eb30b8529428f683b5154a0054c0ee990d3185c7abf')
validpgpkeys=('B0F4253373F8F6F510D42178520A9993A1C052F8')

build() {
    cd "$srcdir"/nginx-$_nginxver

    # Cribbed from aur/nginx-mainline-mod-http-xslt-filter by Sergey Shatunov
    opts=$(nginx -V 2>&1 | grep 'configure arguments' | sed -r 's@^[^:]+: @@')
    IFS=$'\n' opts=( $(xargs -n1 <<< "$opts") )
    ./configure "${opts[@]}" --add-dynamic-module=../$_modname-$pkgver

    make modules
}

package() {
    cd "$srcdir"/nginx-$_nginxver/objs
    for mod in *.so; do
        install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
    done
}