# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Graham Edgecombe <graham@grahamedgecombe.com>

# # I maintain this because:
# AUR version lacks additional optimization and hardening flags
# AUR version builds with discord, benchmark
# AUR version cannot be built offline

pkgname=openrct2
pkgver=0.3.0
_titlepkgver=0.1.2c
_objectpkgver=1.0.16
_replayspkgver=0.0.17
pkgrel=1
pkgdesc='Open source re-implementation of Roller Coaster Tycoon 2 (Original copy required)'
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url='https://openrct2.io'
license=('GPL3')
depends=('hicolor-icon-theme' 'sdl2' 'jansson' 'speexdsp' 'fontconfig'
         'libpng' 'libzip' 'icu')
makedepends=('cmake' 'duktape')
optdepends=('zenity: System dialog box support (GNOME/GTK)'
            'kdialog: System dialog box support (KDE)'
            'alsa-lib: ALSA audio driver'
            'libpulse: PulseAudio audio driver')
install=openrct2.install
source=($pkgname-$pkgver.tar.gz::https://github.com/OpenRCT2/OpenRCT2/archive/v$pkgver.tar.gz
        $pkgname-title-sequences-$_titlepkgver.zip::https://github.com/OpenRCT2/title-sequences/releases/download/v$_titlepkgver/title-sequences.zip
        $pkgname-objects-$_objectpkgver.zip::https://github.com/OpenRCT2/objects/releases/download/v$_objectpkgver/objects.zip
        $pkgname-replays-$_replayspkgver.zip::https://github.com/OpenRCT2/replays/releases/download/v$_replayspkgver/replays.zip
        )
b2sums=('66d956fd85829bc6b4825a59db9f3a3eebbb1e4565a4c8afdb8c05d9d7b3f339f75ff1d9fbc0a0f48d3c0673ac3fc335fb6bec5fe458513de2a0611ccfa3d48d'
        'f91168bea0a4f88a801c95ea45759e0d1c887a89c18dbbded5887d2914db7119dd65c231aa422e4f8a964a81d832eae05bffaa8b7908fac39a63792d082b53a0'
        '7d8d938ba20ce612f7845dce1038134ec60d7e17e0f7d78a67480ae1ae2e6f8dd043f266742acd2dbd8539390349a2dcd7b8c73859a3caef3b5cd8565a4ec1c7'
        '9c22b52302c37abe5e802662eb4b6805fa3e229a71ab9f901b57eee30641ae4b86de9b1315476d158a3feb57c6be2a26c1ccca7c94328fe35bf57b46e2364c32')

prepare() {
  cd "$srcdir/OpenRCT2-$pkgver"
  mkdir data/title
  cp -r $srcdir/*.parkseq data/title
  mkdir data/object
  cp -r $srcdir/official data/object
  cp -r $srcdir/rct1 data/object
  cp -r $srcdir/rct2 data/object
  cp -r $srcdir/rct2tt data/object
  cp -r $srcdir/rct2ww data/object
  mkdir -p testdata/replays
  cp -r $srcdir/*.sv6r testdata/replays
}

build() {
  cd "$srcdir/OpenRCT2-$pkgver"

  # lto breaks compiling
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

  mkdir -p build
  cd build
  cmake -DCMAKE_BUILD_TYPE=RelWithDebInfo    \
        -DCMAKE_INSTALL_PREFIX=/usr          \
        -DCMAKE_INSTALL_LIBDIR=/usr/lib      \
        -DDOWNLOAD_TITLE_SEQUENCES=OFF \
        -DDOWNLOAD_OBJECTS=OFF         \
        -DDOWNLOAD_REPLAYS=OFF         \
        -DDISABLE_NETWORK=ON           \
        -DDISABLE_GOOGLE_BENCHMARK=ON  \
        ..
  make all g2
}

package() {
  cd "$srcdir/OpenRCT2-$pkgver/build"

  make DESTDIR="$pkgdir" install

  rm -rf "$pkgdir/usr/lib"
  rm -rf "$pkgdir/usr/include"
}