# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jelle van der Waa <jelle@archlinux.org>
# Contributor (AUR): Graham Edgecombe <graham@grahamedgecombe.com>

# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
# Arch version builds with discord, benchmark, update checks, online tests
# Arch version cannot be built offline

pkgname=openrct2
pkgver=0.4.6
_titlepkgver=0.4.6
_objectpkgver=1.3.11
_opensfxpkgver=1.0.3
_openmsxpkgver=1.3.1
_replayspkgver=0.0.78
pkgrel=2
pkgdesc='Open source re-implementation of Roller Coaster Tycoon 2 (requires full copy of the game)'
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
url='https://openrct2.io'
license=('GPL3')
depends=('hicolor-icon-theme' 'sdl2' 'speexdsp'
          'fontconfig' 'libpng' 'libzip' 'icu'
         'libogg' 'libvorbis' 'flac')
makedepends=('cmake' 'nlohmann-json')
optdepends=('zenity: System dialog box support (GNOME/GTK)'
            'kdialog: System dialog box support (KDE)'
            'alsa-lib: ALSA audio driver'
            'libpulse: PulseAudio audio driver')
options=('lto')
install=openrct2.install
source=($pkgname-$pkgver.tar.gz::https://github.com/OpenRCT2/OpenRCT2/archive/v${pkgver}.tar.gz
        $pkgname-title-sequences-$_titlepkgver.zip::https://github.com/OpenRCT2/title-sequences/releases/download/v${_titlepkgver}/title-sequences.zip
        $pkgname-objects-$_objectpkgver.zip::https://github.com/OpenRCT2/objects/releases/download/v${_objectpkgver}/objects.zip
        $pkgname-opensfx-$_opensfxpkgver.zip::https://github.com/OpenRCT2/OpenSoundEffects/releases/download/v${_opensfxpkgver}/opensound.zip
        $pkgname-openmsx-$_openmsxpkgver.zip::https://github.com/OpenRCT2/OpenMusic/releases/download/v${_openmsxpkgver}/openmusic.zip
        $pkgname-replays-$_replayspkgver.zip::https://github.com/OpenRCT2/replays/releases/download/v${_replayspkgver}/replays.zip
        )
sha256sums=('80bfbf3a8756a8c98fdf15effcaac42c6cd92c07756c80d00b7dd56d0d0f282a'
            '24a189cdaf1f78fb6d6caede8f1ab3cedf8ab9f819cd2260a09b2cce4c710d98'
            'bf85d88e4fb11ca2e5915567390898747dc2459b3c7a057bdc32b829c91780b4'
            '70be1b6ff8cc24ad8031a2e0cdd445b5dd3c52c886a8e5f70401f75152e4ae6c'
            '0aa9f0e20279ef8e51e46be4c89be6aa44208cec9f46e749c7cd1d5f42ab1005'
            'a6bdfdcc7d916ce060961c5fe7beaf43679fbfad9838cfdbd067617ae0ac0ddf')
b2sums=('910e03586249c6e1fb1320cc47034c121f74da847305a041f18e5d593d1f494a608508b69f5a2b7919a4353eff4ea7d1dc5a5f8236c8857eca8175da04f9ec33'
        '5f7b36cd1372106923000775307ea7ff8c142c3b1d026d84b86f255a629b0a2ac16a682300999789229a8833d4c7327c858c04710ecddfb97af1858ff121a5c4'
        '10a0477fd8db9374b0e667a34ec3b0cedf6cb29fc9b602da845e33272e072c55cf5fd30b9340ec4b763a9f324c72d126290651c9eddef07013857a8228978566'
        '74265800595e36ac943bf2ee5d9c8f6cb3bbd5be3713d9590cb81faac4a75154dfbf9806b1b55e9c2426c84e3cf313a6271fc378ebfd4fa94821683157be5470'
        '0d88423443816c67c87d878263f410abf8850d942dd3ffd92476fa4ce5805005568c4401941433e77f261cffe7a757b3da9a02c6df923316ae41052bb32da5be'
        'cf11a05f6ba5a2808cd4c016ac3c7537a0b49b67fd5ef5ab705aebd4ddc64dd4a82ea12d9c082fe66cebb57437c0d81052bcddfb94a0c9f7aab024a82c2e2ca8')

prepare() {
  cd "$srcdir/OpenRCT2-$pkgver"

  # Add titles data
  mkdir data/sequence
  cp -r --reflink $srcdir/*.parkseq data/sequence

  # Add objects data
  mkdir data/object
  cp -r --reflink $srcdir/official data/object
  cp -r --reflink $srcdir/rct1 data/object
  cp -r --reflink $srcdir/rct2 data/object
  cp -r --reflink $srcdir/rct2tt data/object
  cp -r --reflink $srcdir/rct2ww data/object

  # Add opensfx data
  mkdir data/assetpack
  mkdir data/object/official/audio
  cp -r --reflink $srcdir/assetpack/openrct2.sound.parkap data/assetpack/
  cp -r --reflink $srcdir/object/official/audio/openrct2.audio.additional.parkobj data/object/official/audio/

  # Add openmsx data
  mkdir data/object/official/music
  cp -r --reflink $srcdir/assetpack/openrct2.music.alternative.parkap data/assetpack/
  cp -r --reflink $srcdir/object/official/music/*.parkobj data/object/official/music/

  # Add replays data
  mkdir -p testdata/replays
  cp -r --reflink $srcdir/*.parkrep testdata/replays

  mkdir -p build
}

build() {
  cd "$srcdir/OpenRCT2-$pkgver/build"

  # Needed to be able to build while LTO is enabled
  # https://github.com/OpenRCT2/OpenRCT2/issues/6200
  CXXFLAGS+=" -Wno-error=stringop-overflow -Wno-error=nonnull"

  # Required options to workaround GCC 12 issues
  # https://github.com/OpenRCT2/OpenRCT2/issues/17371
  CXXFLAGS+=" -Wno-error=maybe-uninitialized  -Wno-error=restrict  -Wno-error=null-dereference"

  # Required for -DDISABLE_NETWORK as of 0.3.3
  CXXFLAGS+=" -Wno-error=unused-const-variable"

  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

  cmake -DCMAKE_BUILD_TYPE=Release    \
        -DCMAKE_INSTALL_PREFIX=/usr   \
        -DSTATIC=OFF  \
        -DCMAKE_INSTALL_LIBDIR=/usr/lib      \
        -DDOWNLOAD_TITLE_SEQUENCES=OFF \
        -DDOWNLOAD_OBJECTS=OFF         \
        -DDOWNLOAD_OPENSFX=OFF         \
        -DDOWNLOAD_OPENMSX=OFF         \
        -DDOWNLOAD_REPLAYS=OFF         \
        -DDISABLE_DISCORD_RPC=ON       \
        -DDISABLE_GOOGLE_BENCHMARK=ON  \
        -DDISABLE_HTTP=ON              \
        -DDISABLE_NETWORK=ON           \
        ..
  make all g2
}

package() {
  cd "$srcdir/OpenRCT2-$pkgver/build"

  make DESTDIR="$pkgdir" install

  rm "$pkgdir/usr/lib/libopenrct2.a"
  rmdir "$pkgdir/usr/lib"
}