# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR):  WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor (AUR): Ian Thompson <dalrik370 at gmail dot com>
# Contributor (AUR): Anton Bazhenov <anton.bazhenov at gmail>
# Contributor (AUR): TheBenj88 <thebenj88 *AT* gmail *DOT* com>

# # I maintain this because:
# I use it and it is not in an official repo

pkgname=openxcom
pkgver=1.0
pkgrel=8
pkgdesc="An open-source reimplementation of the famous X-COM game"
arch=('i686' 'x86_64' 'aarch64')
url="https://openxcom.org/"
license=('GPL3')
depends=('sdl_gfx' 'sdl_mixer' 'sdl_image' 'yaml-cpp' 'mesa')
makedepends=('boost' 'glu' 'xmlto' 'docbook-xml' 'docbook-xsl' 'xorgproto')
options=('lto')
install="${pkgname}.install"
source=(${pkgname}-${pkgver}.tar.gz::"https://github.com/SupSuper/OpenXcom/archive/v1.0.tar.gz"
        "openxcom-abs-fix.patch"
        "openxcom-auto_ptr-fix.patch"
        "openxcom-cmath-algorithm-fixes.patch")
b2sums=('ce1c35d3d25e5f327549b3656f4b41d6e37503619c7ccb13ee5382faba905f491c01a0e2af03b70b7237bea3f3fd4a51f7a2be2c44c1feade1b848ad1a414fa3'
        '28792cef812953605053558a85ea555efb27ac0d4225d5a1e480af136fb8c19a1bec7d4c8542c02f020eb376bb4c70fdc68cf8deda1208eeff6bea81136a5ccb'
        '2a4d4743cb112d783a014bf77c63106693aeb9ab8bd74cde8342e06614f4330183756d01eb4559d45d9fc7d583fc4529a302d589c175b4a1a0bbce9b9a7a3a26'
        '633e5ded118bb031cbf0ca3d70d785cd6e757949eeec3adfbfd40b06b8d4c85cc49d3da6ea0e64d4a5a92cad7791b7789c35e8e0501c374d0d24d0cb22d6c21a')

prepare() {
  cd OpenXcom-${pkgver}
  patch -Np1 -i "${srcdir}/openxcom-abs-fix.patch"
  patch -Np1 -i "${srcdir}/openxcom-auto_ptr-fix.patch"
  patch -Np1 -i "${srcdir}/openxcom-cmath-algorithm-fixes.patch"
}

build() {
  cd OpenXcom-${pkgver}
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"
  ./autogen.sh
  ./configure --prefix=/usr --without-docs --disable-werror
  make
}

package() {
  cd OpenXcom-${pkgver}
  make DESTDIR="${pkgdir}" install
}