# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR):  WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor (AUR): artiom <a.mv at gmx dot fr>
# Contributor (AUR): ilikenwf
# Contributor (AUR): American_Jesus

# # I maintain this because:
# AUR version uses git
# AUR version does not use system libs

pkgname=palemoon
pkgver=28.7.2
pkgrel=1
pkgdesc="Open source web browser based on Firefox focusing on efficiency."
arch=(x86_64 i686)
license=(MPL GPL LGPL)
url="https://www.palemoon.org/"
depends=(gtk2 desktop-file-utils libxt startup-notification mime-types dbus-glib
         libpulse alsa-lib
         bzip2 libffi hunspell icu libjpeg-turbo libevent libvpx nspr nss pixman libpng sqlite zlib)
makedepends=(unzip zip python2 yasm
             jack
             autoconf2.13)
optdepends=('ffmpeg: various video and audio support'
            'alsa-utils: ALSA support'
            'jack: Jack support'
            'pulseaudio: PulseAudio support')
source=(palemoon-${pkgver}.tar.gz::https://github.com/MoonchildProductions/UXP/archive/PM${pkgver}_Release.tar.gz
        mozconfig.in
        system-libs.patch)
sha256sums=('3db00c75a8b3383656d6f3624c2ad532d7396371d9e254276c4528d03459d5db'
            '195907ec47d0d5c41783fdb59084d723131a65bc49e79a7b2ac8cfd5ed33a340'
            '20a037116f85737849b663c61b55fdc7120f83e960ba5b416d70a910de0e9443')

prepare() {
  sed 's#%SRCDIR%#'"${srcdir}"'#g' mozconfig.in > mozconfig
  sed -i 's#xlocale#locale#' UXP-PM${pkgver}_Release/intl/icu/source/i18n/digitlst.cpp
}

build() {
  cd UXP-PM${pkgver}_Release

  # I'll use system libs if I darn well choose, thank you very much.
  patch -Np1 -i ../system-libs.patch
  rm build/directive4.py

  export MOZBUILD_STATE_PATH="${srcdir}/mozbuild"
  export MOZCONFIG="${srcdir}/mozconfig"
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
  python2 mach build
}

package() {
  cd pmbuild
  make package
  cd dist
  install -d "${pkgdir}"/usr/{bin,lib}
  cp -r palemoon/ "${pkgdir}/usr/lib/${pkgname}"
  ln -s "/usr/lib/${pkgname}/palemoon" "${pkgdir}/usr/bin/palemoon"

  # icons
  install -Dm644 palemoon/browser/chrome/icons/default/default16.png \
    "${pkgdir}/usr/share/icons/hicolor/16x16/apps/${pkgname}.png"
  install -Dm644 palemoon/browser/chrome/icons/default/default32.png \
    "${pkgdir}/usr/share/icons/hicolor/32x32/apps/${pkgname}.png"
  install -Dm644 palemoon/browser/chrome/icons/default/default48.png \
    "${pkgdir}/usr/share/icons/hicolor/48x48/apps/${pkgname}.png"
  install -Dm644 palemoon/browser/icons/mozicon128.png \
    "${pkgdir}/usr/share/icons/hicolor/128x128/apps/${pkgname}.png"

  # install desktop file
  install -Dm644 "${srcdir}/UXP-PM${pkgver}_Release/application/palemoon/branding/official/palemoon.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}