# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

# # I maintain this because:
# Arch version depends on ModemManager and MM conflicts with NeuG
# # plasma-nm no longer allows disabling MM. :/
# Arch version does not explicitly specify /usr/lib
# Arch version lacks additional optimization and hardening flags

_pkgname=plasma-nm
pkgname=$_pkgname-neug
pkgver=5.27.2
pkgrel=1
pkgdesc='Plasma applet written in QML for managing network connections'
pkgdesc+=", modified to support neug"
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(GPL2)
options=(lto)
depends=(plasma-workspace modemmanager-qt networkmanager-qt)
makedepends=(extra-cmake-modules openconnect)
optdepends=('openconnect: Cisco AnyConnect VPN plugin')
groups=(plasma)
source=(https://download.kde.org/stable/plasma/$pkgver/$_pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('7b247027e3c56eddd00f4ef10288c95fa2c15d567c0de21634666f9fbb3d9096'
            'SKIP')
b2sums=('9982c7cf343df1ae32d8d78abfa15fdf4c729e8c1b22cbd0310802e26c8adacdc9c37e1f9698ecf06a1cd90f689bdb72208f3634764f27ab0128c78ca09a77b3'
        'SKIP')
validpgpkeys=('E0A3EB202F8E57528E13E72FD7574483BB57B18D'  # Jonathan Esk-Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

build() {

  # Fails to build with -fPIE
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"

  cmake -B build -S $_pkgname-$pkgver \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  depends=(rng-tools-openrc-neug)
  conflicts=(plasma-nm)
  provides=(plasma-nm)
  DESTDIR="$pkgdir" cmake --install build
}