# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

# # I maintain this because:
# Arch version depends on ModemManager and MM conflicts with NeuG
# Arch version does not explicitly specify /usr/lib
# Arch version lacks additional optimization and hardening flags

_pkgname=plasma-nm
pkgname=$_pkgname-neug
pkgver=5.25.1
pkgrel=1
pkgdesc='Plasma applet written in QML for managing network connections'
pkgdesc+=", modified to support neug"
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(GPL2)
options=(lto)
depends=(plasma-workspace networkmanager-qt qca-qt5)
makedepends=(extra-cmake-modules openconnect)
optdepends=('openconnect: Cisco AnyConnect VPN plugin')
groups=(plasma)
source=(https://download.kde.org/stable/plasma/$pkgver/$_pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('8973526de047563e7c93185b143606d897a644c694ec9d96f05b52114c233104'
            'SKIP')
b2sums=('34481562ee10350bd045097ef686aa962e347bcb2c5503ccfe4e6ccf0f3527ab4065a52e6aa3dc9f89a386c3b942d392f9b05f075da994b7117a58851b803b15'
        'SKIP')
validpgpkeys=('E0A3EB202F8E57528E13E72FD7574483BB57B18D'  # Jonathan Esk-Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

build() {
  # Fails to build with -fPIE
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all"

  cmake -B build -S $_pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DDISABLE_MODEMMANAGER_SUPPORT=ON
  cmake --build build
}

package() {
  depends=(rng-tools-openrc-neug)
  conflicts=(plasma-nm modemmanager modemmanager-qt)
  provides=(plasma-nm)
  DESTDIR="$pkgdir" cmake --install build
}