# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

# # I maintain this because:
# Arch version depends on ModemManager and MM conflicts with NeuG
# Arch version does not explicitly specify /usr/lib
# Arch version lacks additional optimization and hardening flags

_pkgname=plasma-nm
pkgname=$_pkgname-neug
pkgver=5.22.5
pkgrel=1
pkgdesc='Plasma applet written in QML for managing network connections'
pkgdesc+=", modified to support neug"
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(GPL2)
depends=(plasma-workspace networkmanager-qt qca-qt5)
makedepends=(extra-cmake-modules openconnect)
optdepends=('openconnect: Cisco AnyConnect VPN plugin')
groups=(plasma)
source=(https://download.kde.org/stable/plasma/$pkgver/$_pkgname-$pkgver.tar.xz{,.sig})
b2sums=('0285425f4ed474c38e3a72b8b6654ba17e957921db0372bc24a9ce4fe226186cb687e5ec91836f7bbb1cb2fb9f4da1287efca41cd7b11673e2086477024f4578'
        'SKIP')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

build() {
  # Fails to build with -fPIE
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=auto"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=auto"

  cmake -B build -S $_pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DDISABLE_MODEMMANAGER_SUPPORT=ON
  cmake --build build
}

package() {
  depends=(rng-tools-openrc-neug)
  conflicts=(plasma-nm modemmanager modemmanager-qt)
  provides=(plasma-nm)
  DESTDIR="$pkgdir" cmake --install build
}