# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jiachen Yang <farseerfc@gmail.com>
# Maintainer (AUR): Vlad M. <vlad@archlinux.net>
# Contributor (Arch): Håvard Pettersson <mail@haavard.me>
# Contributor (Arch): Kevin MacMartin <prurigro at gmail dot com>

# # I maintain this because:
# Artix version uses emoticons
# Artix version uses incorrect gpg fingerprints

pkgname=qtox
_pkgname=qTox
pkgver=1.17.2
pkgrel=2.2
_gitver='8eed684c37bd711de2ca4bd863f5f0509edcdc2d'
pkgdesc='a chat, voice, video, and file transfer IM client using the encrypted peer-to-peer Tox protocol'
arch=('x86_64' 'aarch64')
url='https://github.com/qTox/qTox'
license=('GPL3')
depends=('desktop-file-utils'
         'libxss'
         'openal'
         'ffmpeg'
         'qrencode'
         'qt5-svg'
         'sqlcipher'
         'libexif'
         'toxcore'
         'sonnet'
         'libgl')
makedepends=('qt5-tools' 'check' 'cmake' 'mesa' 'libglvnd')

source=( 
        "$pkgname-$pkgver.tar.lz::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz"
        "$pkgname-$pkgver.tar.lz.asc::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz.asc"
        )
b2sums=('80c9c7d94a904a26b31ff14ae027e8d3cce169a5714a8b8d5ca5f4655060c44561700834f14f32b7c22415ff2dd6a5a047d48c0ec2d3fbf7af1599861cf103cc'
        'SKIP')

validpgpkeys=('DA262CC93C0E1E525AD21C8596775D454B8EBF44'  # - sudden6 <sudden6@gmx.at>
              '31039166FA902CA50D05D6085AF9F2E29107C727'  # - Diadlo
              '2880C860D95C909D3DA45C687E086DD661263264'  # - tux3
              '7EB339FE881747E701B7D472EBE36E66A8429B99'  # - AnthonyBilinski
              'CA9221C5389B7C50AA5F779352A50775BE13DF17'  # - noavarice
              '141C880E8BA25B198D0F850F7C132143C1A3A7D4'  # – tox-user
             )

prepare() {
  # disable -Werror for release packaging
  sed -e 's|-Werror||' -i CMakeLists.txt
  sed -e 's|Enable automatic update check" ON|Enable automatic update check" OFF|' -i CMakeLists.txt
}

build() {
  mkdir -p build
  cd build
  # gcc 10.2 + qt 5.15 + pie = segfault
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4"
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
           -DGIT_VERSION=$_gitver \
           -DGIT_DESCRIBE=v$pkgver \
           -DSMILEYS=DISABLED
  make
}

check() {
  cd build
  make test
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}