# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jiachen Yang <farseerfc@gmail.com>
# Maintainer (AUR): Vlad M. <vlad@archlinux.net>
# Contributor (Arch): Håvard Pettersson <mail@haavard.me>
# Contributor (Arch): Kevin MacMartin <prurigro at gmail dot com>

# # I maintain this because:
# Artix version uses emoticons
# Artix version uses incorrect repo
# Artix version uses incorrect gpg fingerprints
# Artix version doesn't use pkgname for source package

pkgname=qtox
_pkgname=qTox
pkgver=1.16.3
pkgrel=8.7
_gitver='8eed684c37bd711de2ca4bd863f5f0509edcdc2d'
pkgdesc='Powerful Tox client written in C++/Qt that follows the Tox design guidelines'
arch=('x86_64' 'aarch64')
url='https://github.com/qTox/qTox'
license=('GPL3')
depends=('desktop-file-utils'
         'libxss'
         'openal'
         'gtk2'
         'ffmpeg'
         'qrencode'
         'qt5-svg'
         'sqlcipher'
         'libexif'
         'toxcore'
         'libgl')
makedepends=('qt5-tools' 'check' 'cmake' 'mesa' 'libglvnd')

source=( 
        "$pkgname-$pkgver.tar.lz::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz"
        "$pkgname-$pkgver.tar.lz.asc::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz.asc"
        )
sha512sums=('97c9becd6a90fc6a09a24fb52c1863dd880d19e9a6807499e875020a4012259f926014d98a4c831fd534028d9bcfcb76c5bb32001a553c22e2174a992a493a65'
            'SKIP')

validpgpkeys=('DA262CC93C0E1E525AD21C8596775D454B8EBF44'  # - sudden6 <sudden6@gmx.at>
              '31039166FA902CA50D05D6085AF9F2E29107C727'  # - Diadlo
              '2880C860D95C909D3DA45C687E086DD661263264'  # - tux3
              '7EB339FE881747E701B7D472EBE36E66A8429B99'  # - AnthonyBilinski
              'CA9221C5389B7C50AA5F779352A50775BE13DF17'  # - noavarice
              '141C880E8BA25B198D0F850F7C132143C1A3A7D4'  # – tox-user
             )

prepare() {
  # disable -Werror for release packaging
  sed -e 's|-Werror||' -i CMakeLists.txt
}

build() {
  mkdir -p build
  cd build
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4 -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4 -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
           -DGIT_VERSION=$_gitver \
           -DGIT_DESCRIBE=v$pkgver \
           -DSMILEYS=DISABLED
  make
}

check() {
  cd build
  make test
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}