# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jiachen Yang <farseerfc@gmail.com>
# Maintainer (AUR): Vlad M. <vlad@archlinux.net>
# Contributor (Arch): Håvard Pettersson <mail@haavard.me>
# Contributor (Arch): Kevin MacMartin <prurigro at gmail dot com>

# # I maintain this because:
# Artix version uses emoticons
# Artix version uses incorrect gpg fingerprints

_offline=0

pkgname=qtox
_pkgname=qTox
pkgver=1.17.3
pkgrel=2
_gitver='8eed684c37bd711de2ca4bd863f5f0509edcdc2d'
pkgdesc='a chat, voice, video, and file transfer IM client using the encrypted peer-to-peer Tox protocol'
arch=('x86_64' 'aarch64')
url='https://github.com/qTox/qTox'
license=('GPL3')
depends=('desktop-file-utils'
         'libxss'
         'openal'
         'ffmpeg'
         'qrencode'
         'qt5-svg'
         'sqlcipher'
         'libexif'
         'toxcore'
         'snorenotify'
         'sonnet'
         'libgl')
makedepends=('qt5-tools' 'check' 'cmake' 'mesa' 'libglvnd')

source=( 
        "$pkgname-$pkgver.tar.lz::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz"
        "$pkgname-$pkgver.tar.lz.asc::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz.asc"
        )
b2sums=('15ea1f6752b675475b6b935d4d4f3c9c123b9f6d82c21238347db9863e81f8315015e071e5dfd3532b2f356caf8c31ba4bbc8a0ab0912c54b685267a87bdd198'
        'SKIP')

validpgpkeys=('DA262CC93C0E1E525AD21C8596775D454B8EBF44'  # - sudden6 <sudden6@gmx.at>
              '31039166FA902CA50D05D6085AF9F2E29107C727'  # - Diadlo
              '2880C860D95C909D3DA45C687E086DD661263264'  # - tux3
              '7EB339FE881747E701B7D472EBE36E66A8429B99'  # - AnthonyBilinski
              'CA9221C5389B7C50AA5F779352A50775BE13DF17'  # - noavarice
              '141C880E8BA25B198D0F850F7C132143C1A3A7D4'  # – tox-user
             )

prepare() {
  # disable -Werror for release packaging
  cd $_pkgname
  sed -e 's|-Werror||' -i CMakeLists.txt
  sed -e 's|Enable automatic update check" ON|Enable automatic update check" OFF|' -i CMakeLists.txt
}

build() {
  cd $_pkgname
  mkdir -p build
  cd build
  # gcc 10.2 + qt 5.15 + pie = segfault
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=auto"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=auto"
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
           -DDESKTOP_NOTIFICATIONS=ON \
           -DGIT_VERSION=$_gitver \
           -DGIT_DESCRIBE=v$pkgver \
           -DSMILEYS=DISABLED
  make
}

# tests require an active public internet connection
if [ "$_offline" == "0" ]; then
check() {
  cd $_pkgname
  cd build
  make test
}
fi

package() {
  cd $_pkgname
  cd build
  make DESTDIR="$pkgdir" install
}