# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): juergen <juergen@archlinux.org>
# Contributor (Arch): Manolis Tzanidakis, Petter Gundersen

# # I maintain this because:
# Arch version does not build all game engines
# Arch version lacks additional optimization and hardening flags

pkgname=scummvm
pkgver=2.1.2
pkgrel=1
pkgdesc="A 'virtual machine' for several classic graphical point-and-click adventure games."
arch=('x86_64')
license=('GPL')
url="http://www.scummvm.org/"
depends=('libpng' 'libtheora' 'sdl2' 'sdl2_net' 'fluidsynth' 'flac' 'faad2' 'libvorbis' 'libmad' 'freetype2'
         'libgl' 'glu' 'libjpeg-turbo' 'libmpeg2' 'curl' 'a52dec')
makedepends=('mesa')
source=("https://scummvm.org/frs/scummvm/${pkgver}/${pkgname}-${pkgver}.tar.xz"
        68758a879e0c8ecc0d40962516d4e808aa4e15e5.patch
        8593a9e1e4e8dd1f5dfac9b1304a417df9a742e6.patch)
b2sums=('0afedd27350ea80c3610106b7e09fd57aaebc8847eebdb180628559ca30f49d005a5466bd3991a76271eff39a782e8abf3bf1a3ace25909a1d9947a1b539d6c2'
        'cf1cf9652bd611bb38e3f4add677e91e9c4cd8fdbf9577433dccb4fb7a288f016f1dd4fc92ab55eb05d2fb1e4071902eec2b63eda8e3f2108b3ed2e63af05005'
        'f3e4fd72d60b453e1393eb0af094fd39e63cf4617181a29ec950e9a6428dc5ccad8b2351bb0e0aa57e97b455aa94603c35a20822a1e88f45e2929920f0fbcd38')

prepare() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  patch -Np1 -i "${srcdir}"/8593a9e1e4e8dd1f5dfac9b1304a417df9a742e6.patch
  patch -Np1 -i "${srcdir}"/68758a879e0c8ecc0d40962516d4e808aa4e15e5.patch
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  # -flto=4 breaks compilation
  export CFLAGS="$CFLAGS -O3 -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"
  ./configure \
    --enable-all-engines \
    --enable-c++11 \
    --enable-release \
    --prefix=/usr
  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
  install -Dm644 dists/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
}