# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): Lone_Wolf <lonewolf@xs4all.nl>
# Contributor (Arch): sausageandeggs <s_stoakley at hotmail.co.uk>

# # I maintain this because:
# Arch version desktop file points to raw executable
# Arch version does not name the music archive

pkgname=singularity
pkgver=1.00
_musicver=025e2696638bcc3bf7690679c3a17c0b46823bbe
pkgrel=7
pkgdesc="Endgame: Singularity - simulation of true AI"
arch=('any')
url="http://emhsoft.com/singularity/index.html"
license=('GPL2' 'custom')
depends=('python' 'python-pygame' 'python-numpy')
makedepends=('python-setuptools')
source=("https://github.com/singularity/singularity/releases/download/v${pkgver}/singularity-${pkgver}.tar.gz"{,.asc}
        singularity-music-${_musicver}.tar.gz::https://github.com/singularity/singularity-music/archive/${_musicver}.tar.gz
        336.diff
        "singularity.desktop")
validpgpkeys=('B3131A451DBFDF7CA05B4197054BBB9F7D806442')
b2sums=('1ca2b120311a19f175014835930610583e8f605dbda3ca3ca96d7e0da86bddeb4b0a264f50a003aa51e05b86ce971255ffda5f498598dde6be370b9a953eb1d0'
        'SKIP'
        '328988697e6a630b7640fa2076fa53ffe5a7c4a3fe4772de6c2ffc4ece3081de4bb57de51159b3ad51f2e54bf796d3775bc40a802e43315aec7767630f8e580f'
        '0be963ca3fac9e7f68dec1c581e1b82dcd41db2b5f77dd3151f01931da872d2b0e7d320bf6b9062a6e0a2c15b6485c69c75d7e1f1dde2f5f0bfbcd95df6cca39'
        '8c59422c8d5cfeb878ded6047bbceb8adc51e4bda74ad1f51a6b96d3b7895106abf3bcf5d70eea234a1325ea3c131643d7c4ba72813d480e651b58d26e3c300a')

prepare() {
  cd "$pkgname-$pkgver"

  cp --reflink -r "$srcdir"/singularity-music-${_musicver}/music singularity/music
  sed -i "s|prune singularity/music|recursive-include singularity/music *|g" MANIFEST.in
  sed -i "s|replaceme|python$(pacman -Q python | cut -d ' ' -f 2 | cut -d . -f 1,2)|g" "$srcdir"/singularity.desktop

  patch -Np1 -i "$srcdir"/336.diff
}

build() {
  cd "$pkgname-$pkgver"

  python setup.py build
}

package() {
  cd "$pkgname-$pkgver"

  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  mv run_singularity.sh "$pkgdir"/usr/bin/singularity

  install -Dm644 "$srcdir/singularity.desktop" "$pkgdir/usr/share/applications/singularity.desktop"
  install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE.cc0.txt LICENSE.CC-BY-SA-3.txt LICENSE.gpl.txt LICENSE.txt
}