# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Harms <thotro at lyse dot net>
# Contributor (AUR): Pascal Grossé <pascal.grosse@gmail.com>

# # I maintain this because:
# AUR version uses /opt
# AUR version uses http
# AUR version uses debug build
# AUR version does not use -O3
# AUR version lacks offline patch
# AUR version lacks DLC

pkgname=tome4
pkgver=1.6.6
pkgrel=1
_offlinever=1.6
_ashesver=1.0.10
_orcsver=1.1.5
_cultsver=1.0.7
pkgdesc="An open-source, single-player, role-playing roguelike game set in the world of Eyal."
pkgdesc+="Includes DLC and offline patch."
arch=('i686' 'x86_64' 'aarch64')
url="https://te4.org/"
license=('custom' 'GPL3')
depends=(glu openal libvorbis sdl2_ttf sdl2_image)
makedepends=(premake zip unzip)
options=(emptydirs)
source=("${url}dl/t-engine/t-engine4-src-${pkgver}.tar.bz2"
  sdl2-path-fix.patch
  O3-support.patch
  offline-donator_${_offlinever}.patch
  ashes-urhrok_${_ashesver}.teaac
  orcs_${_orcsver}.teaac
  cults_${_cultsver}.teaac
  tome4
  tome4.desktop)
conflicts=('tome4-beta' 'tome4-git' 'tome4-nomusic')
b2sums=('f8db817fe32f6d11a6974030d3737dd9e6c80c92bcc6d17f9fff344f47e0e98922b79826701b18e8658d986e3df26c33ca0f4b207a10d049b9270a80ce1e8ac0'
        '200b22bee34c8afce01210cd13cda13997514461249f934b38be48ab346e8df13002379a44c99ebc2d5d5fbf7cf21c07961e202f396a5eb1b9284b0611165e2b'
        '54e069a67db8911f003e60da3496455bd21466a3dc6d4253fa14e513cfc4eee6dbe3d3165fb93aeb9bd097f26b2035d1c60cfa171020325d695af1392300faa6'
        'ac66d8cd615d8f5cf9cf8dce140670ebf7b30fdf2d0b84b3d66160ffd740c29324b81dfb589435802308fdcdc5d357f9b09fdab28c43e682e5317acebeb9d49d'
        '1f07c035431337bb10fce5f6cdf6669086622e90f5e3c3f50450448091a7aa270ca0d1b243a8102e0e0a1d93e5991fceb1091aa8db5235301185889701fee563'
        '6faae8adbe66af3dcd29f554840acd5b7b8e49dbf731bb53294c9619ae439042d61440d092d922b424f69bf1fd9464a6085ad06ad2fc38d3742ce9e6e8c9b38e'
        '1ebdb1ada1ee5fa3a1285258b522030b128ad004c68088e9f82af03cc3ec68d218e3fe5bddaf57372e8e2ad58c7df158b33ff9d029ef4b8b2227c5684128d17f'
        'd32a8d25c7cdd7d13d530272e880381153fa86a5e99135481559eb81b0c1188dec2aabc1ef7a024b3791da17e2e9e1112a267261b43d49043dc81fb5622645cb'
        '763a8a8a27d8bb94f895489fe2f622f72eee3c7116ab8507235197ba9e3ab996aa2a16ce5f726eab47d361d35b044654b91bdca5742678417116ef18dcb07989')


###############################################################################
# 1. Patch the game.
###############################################################################
prepare() {
  cd t-engine4-src-${pkgver}

  patch -p1 -i "${srcdir}/sdl2-path-fix.patch"
  patch -p1 -i "${srcdir}/O3-support.patch"
  patch -p1 -i "${srcdir}/offline-donator_${_offlinever}.patch"
  cp "${srcdir}/ashes-urhrok_${_ashesver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/ashes-urhrok.teaac"
  cp "${srcdir}/orcs_${_orcsver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/orcs.teaac"
  cp "${srcdir}/cults_${_cultsver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/cults.teaac"

}

###############################################################################
# 2. Build the game engine from source.
###############################################################################
build() {
  cd t-engine4-src-${pkgver}

  premake4 gmake
  # lto breaks compiling
    export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIE"
    export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIE"
    export LDFLAGS="$LDFLAGS,-pie"
  make config=release
}

###############################################################################
# 3. Create the package. Copy all that shall be installed into the package dir.
###############################################################################
package() {
  # Extract and install the icon.
  unzip -oj -qq "${srcdir}/t-engine4-src-${pkgver}/game/engines/te4-${pkgver}.teae" "data/gfx/te4-icon.png" -d "${srcdir}"
  install -Dm644 "${srcdir}/te4-icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  
  # Install the documents.
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CONTRIBUTING" "${pkgdir}/usr/share/doc/${pkgname}/CONTRIBUTING"
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CREDITS" "${pkgdir}/usr/share/doc/${pkgname}/CREDITS"
  
  # Install the custom license into standard location.
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING-MEDIA" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING-MEDIA"

  # Install the game executable, and the launcher.
  install -Dm755 "${srcdir}/t-engine4-src-${pkgver}/t-engine" "${pkgdir}/usr/lib/${pkgname}/t-engine"
  install -Dm755 "${srcdir}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  
  # Install the game data.
  cp -r "${srcdir}/t-engine4-src-${pkgver}/bootstrap" "${pkgdir}/usr/lib/${pkgname}/"
  cp -r "${srcdir}/t-engine4-src-${pkgver}/game" "${pkgdir}/usr/lib/${pkgname}/"
}