# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Harms <thotro at lyse dot net>
# Contributor (AUR): Pascal Grossé <pascal.grosse@gmail.com>

# # I maintain this because:
# AUR version uses /opt
# AUR version lacks DLC
# AUR version lacks offline patch
# AUR version lacks glext patch
# AUR version does not use -O3
# AUR version uses http
# AUR version uses debug build

pkgname=tome4
pkgver=1.5.10
pkgrel=4
pkgdesc="An open-source, single-player, role-playing roguelike game set in the world of Eyal."
pkgdesc+="Includes DLC and offline patch."
arch=('i686' 'x86_64')
url="https://te4.org/"
license=('custom' 'GPL3')
depends=(glu openal libvorbis sdl2_ttf sdl2_image)
makedepends=(premake zip unzip)
options=(!makeflags emptydirs)
source=("${url}dl/t-engine/t-engine4-src-${pkgver}.tar.bz2"
	sdl2-path-fix.patch
	glext-include-removal.patch
	O3-support.patch
	offline-donator.patch
	ashes-urhrok.teaac
	orcs.teaac
	cults.teaac
	tome4
	tome4.desktop)
conflicts=('tome4-beta' 'tome4-git' 'tome4-nomusic')
sha256sums=('a76d29d2c0b964e9ab121873041c55930db1a0ccdaf877228dcba62ee06b8555'
            '37f5be7020a06228b7d22f4c622ab5a8843b4dbea7493d7e3b324bd592cd818e'
            '04e7fc180b1df55c63c91a0c59bbd092db0995db5600a168a6e68458b49327a8'
            '3e8c53ef138edc00ccbffed840dca89df973e688497e8bd2f9cf9d84826c3618'
            '7fda796a4ce59dc02e4bb21a07c190133a6c8da678bccba4437ea5704e69014c'
            '5e5e28b44a4ff154f4a86aca17d35aa6da70c5c3ca2ef38b45a61eb3ddbb2c8f'
            '2bf91a7a65690f813478f839bf2ebb48af76f9669f7d94b4fa1a43d8b0216017'
            'a392bf93c83baa3cdb4d29d7ae6e8d27e3a2e7ba5bf4cdd139c9ac15bfd6cd8e'
            '6025412fb06aea306b64c41c7248d5f667e0cc219a84b6c6ac01e3606883f672'
            '3c62282014b848a009f9f659fcacfea4f7bb07d437200866b4438630c90b8cd7')

###############################################################################
# 1. Patch the game.
###############################################################################
prepare() {
	cd "$srcdir"/t-engine4-src-${pkgver}
	patch -p1 -i "${srcdir}/sdl2-path-fix.patch"
	patch -p1 -i "${srcdir}/glext-include-removal.patch"
	patch -p1 -i "${srcdir}/O3-support.patch"
	patch -p1 -i "${srcdir}/offline-donator.patch"
	cp "${srcdir}/ashes-urhrok.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/"
	cp "${srcdir}/orcs.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/"
	cp "${srcdir}/cults.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/"

}

###############################################################################
# 2. Build the game engine from source.
###############################################################################
build() {
	cd t-engine4-src-${pkgver}
	premake4 gmake
	make -j4 config=release
}

###############################################################################
# 3. Create the package. Copy all that shall be installed into the package dir.
###############################################################################
package() {
	# Extract and install the icon.
	unzip -oj -qq "${srcdir}/t-engine4-src-${pkgver}/game/engines/te4-${pkgver}.teae" \
		"data/gfx/te4-icon.png" -d "${srcdir}"
	install -Dm644 "${srcdir}/te4-icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
	
	# Install the documents.
	install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CONTRIBUTING" "${pkgdir}/usr/share/doc/${pkgname}/CONTRIBUTING"
	install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CREDITS" "${pkgdir}/usr/share/doc/${pkgname}/CREDITS"
	
	# Install the custom license into standard location.
	install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
	install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING-MEDIA" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING-MEDIA"

	# Install the game executable, and the launcher.
	install -Dm755 "${srcdir}/t-engine4-src-${pkgver}/t-engine" "${pkgdir}/usr/lib/${pkgname}/t-engine"
	install -Dm755 "${srcdir}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
	install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
	
	# Install the game data.
	cp -r "${srcdir}/t-engine4-src-${pkgver}/bootstrap" "${pkgdir}/usr/lib/${pkgname}/"
	cp -r "${srcdir}/t-engine4-src-${pkgver}/game" "${pkgdir}/usr/lib/${pkgname}/"
}