# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Harms <thotro at lyse dot net>
# Contributor (AUR): Pascal Grossé <pascal.grosse@gmail.com>

# # I maintain this because:
# AUR version uses /opt
# AUR version uses http
# AUR version uses debug build
# AUR version does not use -O3
# AUR version lacks offline patch
# AUR version lacks DLC

pkgname=tome4
pkgver=1.6.0
pkgrel=1
_offlinever=1.6
_ashesver=1.0.7
_orcsver=1.0.5
_cultsver=1.0.3
pkgdesc="An open-source, single-player, role-playing roguelike game set in the world of Eyal."
pkgdesc+="Includes DLC and offline patch."
arch=('i686' 'x86_64')
url="https://te4.org/"
license=('custom' 'GPL3')
depends=(glu openal libvorbis sdl2_ttf sdl2_image)
makedepends=(premake zip unzip)
options=(!makeflags emptydirs)
source=("${url}dl/t-engine/t-engine4-src-${pkgver}.tar.bz2"
  sdl2-path-fix.patch
  O3-support.patch
  offline-donator_${_offlinever}.patch
  ashes-urhrok_${_ashesver}.teaac
  orcs_${_orcsver}.teaac
  cults_${_cultsver}.teaac
  tome4
  tome4.desktop)
conflicts=('tome4-beta' 'tome4-git' 'tome4-nomusic')
sha512sums=('b36ebdb7cf5c77a6e3c27a51c6282c5dec47fd8c27463c514b83f4b6f98300fe976ebb1618fc208146ff0287049bb91865876ab14cef3b4ad8198975cbea688e'
            '9d4533581e6dea76a68ed8feb5aded7d02562ce3303c5c8a59f041a2b52f49bb3aa215d3f2ba3e31af85c62655ba1494d1e0f626bcbb618a90f053fd1f364a48'
            '790dce2ee4f42f0bdb536eed464f2f9849039852249deb1de06f2e71e2938cb70380ad6b617900b4b159f60060a4163a37583e3c1639578b090cc77621243477'
            '9f19607d542bfed80570875f22211e9cda3576c62e1cdd426576b8d3832e7b9af2e86135ee0c25942772fbe1f10bdb63d62cd37a59f31a424518cdfd9097d536'
            '2e47706326f443838f265b9345a53b2b7ae548c0277da14725dae414187760c5d92eb38ff3b851cb31ac8794f8cc38631cd5c70b8ff4b9acd66eeb9d29a18870'
            '3181815df9463f32e1592643c7c62dd39485a982b65d0fb40fac94e62233a0fd72d325bc0d088e2efb2a6837dad6377777db0c242d680c00a1714ca59c4950f9'
            'd66c85168e8ed7fcb79dea78ddf0213ff8d473cd278ce6ea07f6b4f4eb2b98d6bec8b7683e1957404441b1c94cc74d0df816ce9e77a2a192a5449aacff982bab'
            '521e99b07082d6379606541f625f68fa666610e1c3f27e5e4803cc44bc16e60f28824792d1b13e477a08176f609288e693be3d92ba60cb4fea343f11854fe466'
            '94ed400247d4137fc4f6e770e724a47a028a2fafff15c38ba952d828db4d3890e13ae2c51b8cf9e070b545ba07e5c183b44c15886480b1e06d3c94a2826e5c73')


###############################################################################
# 1. Patch the game.
###############################################################################
prepare() {
  cd t-engine4-src-${pkgver}

  patch -p1 -i "${srcdir}/sdl2-path-fix.patch"
  patch -p1 -i "${srcdir}/O3-support.patch"
  patch -p1 -i "${srcdir}/offline-donator_${_offlinever}.patch"
  cp "${srcdir}/ashes-urhrok_${_ashesver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/ashes-urhrok.teaac"
  cp "${srcdir}/orcs_${_orcsver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/orcs.teaac"
  cp "${srcdir}/cults_${_cultsver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/cults.teaac"

}

###############################################################################
# 2. Build the game engine from source.
###############################################################################
build() {
  cd t-engine4-src-${pkgver}

  premake4 gmake
    export CFLAGS="$CFLAGS -fstack-protector-all -fPIE"
    export CXXFLAGS="$CXXFLAGS -fstack-protector-all -fPIE"
    export LDFLAGS="$LDFLAGS,-pie"
  make -j4 config=release
}

###############################################################################
# 3. Create the package. Copy all that shall be installed into the package dir.
###############################################################################
package() {
  # Extract and install the icon.
  unzip -oj -qq "${srcdir}/t-engine4-src-${pkgver}/game/engines/te4-${pkgver}.teae" "data/gfx/te4-icon.png" -d "${srcdir}"
  install -Dm644 "${srcdir}/te4-icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  
  # Install the documents.
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CONTRIBUTING" "${pkgdir}/usr/share/doc/${pkgname}/CONTRIBUTING"
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CREDITS" "${pkgdir}/usr/share/doc/${pkgname}/CREDITS"
  
  # Install the custom license into standard location.
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING-MEDIA" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING-MEDIA"

  # Install the game executable, and the launcher.
  install -Dm755 "${srcdir}/t-engine4-src-${pkgver}/t-engine" "${pkgdir}/usr/lib/${pkgname}/t-engine"
  install -Dm755 "${srcdir}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  
  # Install the game data.
  cp -r "${srcdir}/t-engine4-src-${pkgver}/bootstrap" "${pkgdir}/usr/lib/${pkgname}/"
  cp -r "${srcdir}/t-engine4-src-${pkgver}/game" "${pkgdir}/usr/lib/${pkgname}/"
}