# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): aksr <aksr at t-com dot me>
# Contributor (AUR): sekret
# Contributor (AUR): Kyle Keen <keenerd@gmail.com>
# Contributor (AUR): Henning Garus <henning.garus@gmail.com>
# Contributor (AUR): Joshua Stiefer <facedelajunk@gmail.com>

# # I maintain this because:
# AUR version doesn't use system libs
# AUR version uses doesn't use pkgname for source package
# AUR version has excesssive checksums

pkgname=wordgrinder
pkgver=0.7.2
pkgrel=1
pkgdesc="A word processor for processing words."
url="http://cowlark.com/wordgrinder/"
arch=('i686' 'x86_64')
license=('MIT')
makedepends=(ninja)
checkdepends=()
depends=('freetype2' 'libx11' 'libxft' 'lua' 'minizip' 'ncurses' 'uthash' 'zlib')
source=("$pkgname-$pkgver.tar.gz::https://github.com/davidgiven/$pkgname/archive/$pkgver.tar.gz")
sha256sums=('4e1bc659403f98479fe8619655f901c8c03eb87743374548b4d20a41d31d1dff')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i '7s!$(HOME)!'$pkgdir'/usr!' Makefile
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make CURSES_PACKAGE=ncurses LUA_PACKAGE=lua MINIZIP_PACKAGE=minizip \
  UTHASH_PACKAGE='--cflags={-I/usr/include} --libs={-L/usr/include}'

}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX="$pkgdir/usr" install
  cd licenses
  for i in COPYING.LuaBitOp COPYING.LuaFileSystem \
           COPYING.Scowl COPYING.wcwidth \
           COPYING.WordGrinder COPYING.xpattern; do
  install -Dm644 $i "$pkgdir/usr/share/licenses/$pkgname/$i"
  done
}