# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Parabola): David P. <megver83@parabola.nu>
# Maintainer (Hyperbola): Luke R. <g4jc@openmailbox.org>
# Maintainer (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Parabola): André Silva <emulatorman@hyperbola.info>
# Contributor (Parabola): Márcio Silva <coadde@hyperbola.info>

# # I maintain this because:
# Required to build linux-libre-firmware
# Parabola version patch name is too vague
# Parabola version uses bz2 source package

_target=xtensa-elf
pkgname=$_target-binutils
pkgver=2.33.1
pkgrel=1
pkgdesc='A set of programs to assemble and manipulate binary and object files for the Xtensa target'
arch=('x86_64' 'i686' 'armv7h')
url="https://www.gnu.org/software/binutils/"
license=('GPL')
depends=('zlib')
source=("https://ftp.gnu.org/gnu/binutils/binutils-$pkgver.tar.xz"{,.sig}
        'xtensa-elf-binutils.patch::https://github.com/qca/open-ath9k-htc-firmware/raw/master/local/patches/binutils.patch')
b2sums=('c336a8412938dc8c224f40a763a8bea9937cca0462a8fb80e62f14aabe590107fc061a3f4b9327e1f4652cb026384d36a91b4766d4d469d2d0680932874b638c'
        'SKIP'
        '839127d83d08856cbaa29cc83436f26b0ffc8a2f96d7c4cc49746c37f47d0a5da2f6d0ac78723efaef63807f52643630bd76ff39526167d0d169b5c3bce9f21d')
validpgpkeys=('EAF1C276A747E9ED86210CBAC3126D3B4AE55E93'  # Tristan Gingold <gingold@adacore.com>
              '3A24BC1E8FB409FA9F14371813FCEF89DD9E3C4F') # Nick Clifton (Chief Binutils Maintainer) <nickc@redhat.com>

prepare() {
  cd binutils-$pkgver
  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
  patch -p1 -i ../xtensa-elf-binutils.patch
}

build() {
  cd binutils-$pkgver

  if [ "${CARCH}" != "i686" ]; then
    # enabling gold linker at i686 makes the install fail
    enable_gold='--enable-gold'
  fi

  ./configure --target=$_target \
              --with-sysroot=/usr/$_target \
              --prefix=/usr \
              --disable-multilib \
              --with-gnu-as \
              --with-gnu-ld \
              --disable-nls \
              --enable-ld=default \
              $enable_gold \
              --enable-plugins \
              --enable-deterministic-archives

  make
}

check() {
  cd binutils-$pkgver
  
  # unset LDFLAGS as testsuite makes assumptions about which ones are active
  # do not abort on errors - manually check log files
  make LDFLAGS="" -k check || true
}

package() {
  cd binutils-$pkgver

  make DESTDIR="$pkgdir" install

  # Remove file conflicting with host binutils and manpages for MS Windows tools
  rm "$pkgdir"/usr/share/man/man1/$_target-{dlltool,windres,windmc}*

  # Remove info documents that conflict with host version
  rm -r "$pkgdir"/usr/share/info
}