Initial commit

1 files changed, 64 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..e161f9e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,64 @@
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
+# Contributor (Arch): t3ddy  <t3ddy1988 "at" gmail {dot} com>
+# Contributor (Arch): Adrián Chaves Fernández (Gallaecio) <adriyetichaves@gmail.com>
+
+# # I maintain this because:
+# Arch version lacks additional optimization and hardening flags
+
+pkgname=0ad
+pkgver=a23.1
+_pkgver=0.0.23b-alpha
+pkgrel=5.2
+pkgdesc="Cross-platform, 3D and historically-based real-time strategy game"
+arch=('x86_64')
+url="https://play0ad.com/"
+license=('GPL2' 'CCPL')
+depends=('binutils' 'boost-libs' 'curl' 'enet' 'libogg' 'libpng' 'libvorbis'
+         'libxml2' 'openal' 'sdl2' 'wxgtk' 'zlib' 'libgl' '0ad-data' 'glu'
+         'gloox' 'miniupnpc' 'libminiupnpc.so' 'icu' 'nspr' 'libsodium')
+makedepends=('boost' 'cmake' 'mesa' 'zip' 'python2' 'libsm')
+source=("https://releases.wildfiregames.com/$pkgname-$_pkgver-unix-build.tar.xz")
+sha512sums=('82934313c46c4fd89e3841d5bbf901904abbd2108e9749529d7282bd24ac53b9e6878681c06e6019f4d8ec0e425c28300b0aafc9610a66a331777ffb58ed6135')
+
+prepare() {
+  cd "$srcdir/$pkgname-$_pkgver/"
+  sed -i "s/env python/env python2/g" libraries/source/cxxtest-4.4/bin/cxxtestgen
+}
+
+build() {
+  cd "$srcdir/$pkgname-$_pkgver/build/workspaces"
+
+  unset CPPFLAGS # for le spidermonkey
+
+  # http://site.icu-project.org/download/61#TOC-Migration-Issues
+  CXXFLAGS+=' -DU_USING_ICU_NAMESPACE=1'
+
+  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
+  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
+
+  export SDL2_CONFIG="pkg-config sdl2"
+  ./update-workspaces.sh \
+      --without-pch \
+      --bindir=/usr/bin \
+      --libdir=/usr/lib/0ad \
+      --datadir=/usr/share/0ad/data
+
+  cd "$srcdir/$pkgname-$_pkgver/build/workspaces/gcc"
+
+  verbose=1 make
+}
+
+package() {
+  install -d "${pkgdir}"/usr/{bin,lib/0ad,share/"${pkgname}"/data}
+  cd "$srcdir/$pkgname-$_pkgver"
+
+  install -Dm755 binaries/system/pyrogenesis "${pkgdir}/usr/bin"
+  install -Dm755 binaries/system/*.so "${pkgdir}/usr/lib/0ad"
+
+  cp -r binaries/data/l10n/ ${pkgdir}/usr/share/${pkgname}/data/
+
+  install -Dm755 build/resources/${pkgname}.sh "${pkgdir}/usr/bin/${pkgname}"
+  install -Dm644 build/resources/${pkgname}.desktop "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  install -Dm644 build/resources/${pkgname}.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
+}