blob: c8309ced7d0a6394502cbcd6a9be451c02dca58c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): t3ddy <t3ddy1988 "at" gmail {dot} com>
# Contributor (Arch): Adrián Chaves Fernández (Gallaecio) <adriyetichaves@gmail.com>
# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
pkgname=0ad
pkgver=a24.b
_pkgver=0.0.24b-alpha
pkgrel=4
pkgdesc="Cross-platform, 3D and historically-based real-time strategy game"
arch=('x86_64')
url="https://play0ad.com/"
license=('GPL2' 'CCPL')
depends=('0ad-data' 'binutils' 'boost-libs' 'curl' 'enet' 'libogg' 'libpng' 'libvorbis'
'libxml2' 'openal' 'sdl2' 'wxgtk3' 'zlib' 'libgl' 'glu' 'fmt'
'gloox' 'miniupnpc' 'libminiupnpc.so' 'icu' 'nspr' 'libsodium')
makedepends=('boost' 'cmake' 'mesa' 'zip' 'libsm' 'rust')
source=("https://releases.wildfiregames.com/$pkgname-$_pkgver-unix-build.tar.xz"
$pkgname-rust-1.50.patch::https://github.com/0ad/0ad/commit/087a277e66c0456c2d6fdb7403d032ad09cbd18b.patch)
b2sums=('a724abba6bed4b580670588e9dcfe0f75f6cef0fbde6ad666356e96213c685932edd0a1daafb5dd04206870c2c8222340c9c51e83076ec2911cbb5377ca00666'
'6b77253a0778c5923e1f1b7ce6102c846f2f85f013fc4cbced0b7e94da6daa776ce45c0d6dff93715648c0db5eed587b8cd77fb1162fa34a4cda4c40613ecea7')
prepare() {
cd "$pkgname-$_pkgver"
patch -Np1 -i ../$pkgname-rust-1.50.patch
}
build() {
cd "$pkgname-$_pkgver/build/workspaces"
# rust is prone to OOM, use 1 thread per 2GB ram
#export MAKEFLAGS="-j32"
# -fPIE and -pie break compilation
# -flto=auto and -flto=1 break compilation since a24.b
export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"
export WX_CONFIG="wx-config-gtk3"
./update-workspaces.sh $MAKEFLAGS \
--without-pch \
--bindir=/usr/bin \
--libdir=/usr/lib/0ad \
--datadir=/usr/share/0ad/data
cd gcc
VERBOSE=1 make
}
package() {
cd "$pkgname-$_pkgver"
install -d "${pkgdir}"/usr/{bin,lib/0ad,share/"${pkgname}"/data}
install -Dm755 binaries/system/pyrogenesis "${pkgdir}/usr/bin"
install -Dm755 binaries/system/*.so "${pkgdir}/usr/lib/0ad"
cp -r binaries/data/l10n/ "${pkgdir}/usr/share/${pkgname}/data/"
install -Dm755 build/resources/${pkgname}.sh "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 build/resources/${pkgname}.desktop "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm644 build/resources/${pkgname}.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}
|
