PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (AUR): Lex Black <autumn-wind at web dot de>
# Contributor (AUR): xnitropl <xnitropl at gmail dot com>
# Contributor (AUR): Anton Larionov <diffident dot cat at gmail dot com>

# # I maintain this because:
# AUR version uses /opt

pkgname=7kaa
pkgver=2.15.0
pkgrel=1
pkgdesc='Seven Kingdoms: Ancient Adversaries is a real-time strategy (RTS) computer game developed by Trevor Chan'
url='https://7kfans.com/'
arch=('i686' 'x86_64')
license=('GPL2')
depends=('openal' 'desktop-file-utils' 'enet' 'gcc-libs' 'sdl2')
optdepends=('7kaa-music: for ingame music')
conflicts=('7kaa-data')
provides=('7kaa-data')
source=("https://github.com/the3dfxdude/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "${pkgname}.sh"
        "${pkgname}.desktop"
        "${pkgname}.ico")
sha512sums=('99a13b57533fd31b0b6386dbb71e4955aafb7ca08af0075cf0704d8bd0583ccf7b4efc2a920f1d3df75955f916cca481156019e246dc75adaa9c379f3b5d7110'
            '989985576312222fe6f5a2c12ed4f37078a242bd57fbfa5613689fb7dd406064d49982ab325dab6fc5c4bd8247d58f6b91931abcdcb05b6ca2ea9169f30cc986'
            'f0fcc0c518b1e89ad88e1a71cfccd0f6297a3b7e1ba502185278277976e7da8c20db2e08f6b600c8c02013acd138ec2153ca28af05deed5a08eafbdfa29dfb10'
            '9cc724622be339f1eeb437b5900745781817c9771039e732ad73e3aae2be2f5b5d78dc8cc06c8af42e38de9acda5e0f5d50a2669ce6d3c8f6c50c04c50687d41')


build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure
  make
}

package() {
  # install data files
  install -dm755 "${pkgdir}/usr/lib/7kaa/"
  cd "${srcdir}/$pkgname-$pkgver/data/"
  cp -r {encyc,encyc2,image,resource,scenari2,scenario,sound,sprite,tutorial} "${pkgdir}/usr/lib/7kaa/"

  # fix permissions
  cd "${pkgdir}/usr/lib/7kaa/"
  find . -type d -exec chmod 755 {} \;

  # copy readme
  install -D -m644 "${srcdir}/$pkgname-$pkgver/README" "${pkgdir}/usr/share/doc/7kaa/README"

  # main file
  install -dm755 "${pkgdir}/usr/lib/${pkgname}/"
  install -D -m755 "${srcdir}/${pkgname}-${pkgver}/src/${pkgname}" "${pkgdir}/usr/lib/${pkgname}/${pkgname}"

  # bash script
  install -D -m755 "$srcdir/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"

  # desktop entry
  install -D -m644 "$srcdir/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -D -m644 "${srcdir}/${pkgname}.ico" "${pkgdir}/usr/share/pixmaps/${pkgname}.ico"
}