1 files changed, 50 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..c4028d0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (AUR): Christian Hesse <arch@eworm.de>
+# Contributor (AUR): speps <speps at aur dot archlinux dot org>
+
+# # I maintain this because:
+# I use it and it is not in an official repo
+
+pkgname=apulse
+pkgver=0.1.12
+pkgrel=1
+pkgdesc='PulseAudio emulation for ALSA'
+arch=('i686' 'x86_64')
+url='https://github.com/i-rinat/apulse'
+license=('custom:MIT')
+depends=('alsa-lib' 'glib2')
+makedepends=('cmake')
+install=apulse.install
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
+        'asoundrc.sample')
+b2sums=('04d88a298ff5e21e19fda1979ebbc96a6441f83212d6903a004a54ee360276985e66b637571a76e3fe6821d42762ac515b02a8a2cb0149a66f3150e34bd0d9b7'
+        '9daa8dbd6de6ec2855ae0105cd9f5cc2edf17af08286d209d15473f626a6a8e0073ebe79da640e0059c6224bcbde49dfab214029bfcf758c8a19439548c0fcec')
+
+prepare() {
+	cd apulse-${pkgver}
+
+	mkdir -p build
+}
+
+build() {
+	cd apulse-${pkgver}/build
+
+	cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
+		-DCMAKE_BUILD_TYPE=Release
+	make
+}
+
+package() {
+	cd apulse-${pkgver}/build
+
+	make DESTDIR="${pkgdir}/" install
+
+	# sample asoundrc
+	install -Dm644 ../../${source[1]} \
+		"${pkgdir}/usr/share/${pkgname}/${source[1]}"
+
+	# license
+	install -Dm644 ../LICENSE.MIT \
+		"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+