path: root/PKGBUILD

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Kyle Keen <keenerd@gmail.com>

# # I maintain this because:
# Arch version is not BN
# Arch version has non-functional desktop file
# Arch version lacks additional optimization and hardening flags
# Arch version lacks the MSX++UnDeadPeopleEdition tileset
# Arch version lacks the @ soundpack
# Arch version lacks the CO.AG musicpack

pkgbase=cataclysm-bn
pkgname=(cataclysm-bn cataclysm-bn-tiles)
pkgname=cataclysm-bn
_pkgname=Cataclysm-BN-cbn-experimental
pkgver=202112061544
_pkgver=2021-12-06-1544
pkgrel=1
pkgdesc="A post-apocalyptic roguelike."
#url="http://cataclysmrl.blogspot.com/"
#url="http://www.cataclysm.glyphgryph.com/"
#url="http://en.cataclysmdda.com/"
url="https://github.com/cataclysmbnteam/Cataclysm-BN"
arch=('x86_64' 'aarch64')
license=("CCPL:by-sa")
depends=('ncurses' 'hicolor-icon-theme' 'gettext')
makedepends=('sdl2_image' 'sdl2_ttf' 'sdl2_mixer' 'freetype2' 'astyle')
source=("$pkgname-$_pkgver.tar.gz::https://github.com/cataclysmbnteam/Cataclysm-BN/archive/refs/tags/cbn-experimental-$_pkgver.tar.gz"
        "cataclysm-bn.desktop"
        "cataclysm-bn-tiles.desktop"
        "icon_128x128.png"

        "ammo-01_inconsistent-ammo-names.patch"
        "ammo-02_fix-20x66mm-loudness.patch"
        "ammo-03_fix-reloaded-50bmg.patch"
        "ammo-04_fix-missing-ammo-frag-effects.patch"
        "ammo-05_22-casings-can-stack.patch"
        "ammo-10_ammo-order-fix.patch"

        "armor-01_ankle-ammo-pouch-is-not-a-backpack.patch"
        "armor-02_fix-survivor-fingerless-gloves-warmth.patch"

        "bionics-01_npc-can-use-more-bionics.patch"

        "foods-01_fix-food-materials.patch"

        "itemgroups-01_hk46-is-milspec.patch"
        "itemgroups-02_add-missing-mre.patch"

        "monsters-01_medical-zombies-called-zombies.patch"

        "mutations-01_nerf-lightstep.patch"
        "mutations-02_fix-evac3-background-visible.patch"

        "recipes-01_fix-brioche-cooking-time.patch"
        "recipes-02_4570-dragon-can-be-dismantled.patch"

        "terrain-01_quiverfull-house-correct-stairs.patch"
        "terrain-02_tacoma-barn-door-position.patch"
        "terrain-03_tacoma-clinic-add-missing-floor.patch"
        "terrain-04_lumbermill-gasoline-not-spilled.patch"
        "terrain-05_community-garden-fertilizer-not-spilled.patch"
        "terrain-06_fix-doors-for-npcs.patch"
        "terrain-07_rehide-redacted.patch"
        "terrain-08_derelict-shed-is-s.patch"
        "terrain-09_make-firestation-shelter-wells-npc-drinkable.patch"

        "tools-01_foldable-bottle-is-container.patch"
        "tools-02_vacutainer-is-not-a-weapon.patch"
        "tools-03_shears-use-light-battery.patch"
        "tools-04_normalize-drone-volume.patch"

        "vehicles-01_portable-generator-engine.patch"

        "etc-01_fix-rubbersplosion.patch"
        "etc-02_add-missing-price-postapoc.patch"
        "etc-03_revert-book-revamp.patch"

        "jc_radio-can-use-ups.patch"
        "jc_ammo-loudness-ap-times-2.patch"
        "jc_allow-bio-firestarter-on-smoker.patch"
        "jc_stop-non-faction-npc-sleep-depirvation.patch"
        "jc_stop-non-faction-npc-malnourishment.patch"
        "jc_stop-sleeping-on-tables.patch"
        "jc_allow-hacker-laptop.patch"
        "jc_restore-removed-traits.patch"
        "jc_more-military-base-overmap.patch"
        "jc_npc-eat-from-further-camp.patch"
        
        "custom.patch"

        "cataclysm-dda-tileset_undeadpeople.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-tileset_undeadpeople.git/snapshot/cataclysm-dda-tileset_undeadpeople-master.tar.xz"
        "cataclysm-dda-mod_battle-maid-redone-tileset.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-mod_battle-maid-redone-tileset.git/snapshot/cataclysm-dda-mod_battle-maid-redone-tileset-master.tar.xz"
        "cataclysm-dda-soundpack_jcsoundpack.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-soundpack_jcsoundpack.git/snapshot/cataclysm-dda-soundpack_jcsoundpack-master.tar.xz"
        "cataclysm-dda-musicpack_coag-musicpack.tar.xz::https://library.iserlohn-fortress.net/cataclysm-dda-musicpack_coag-musicpack.git/snapshot/cataclysm-dda-musicpack_coag-musicpack-master.tar.xz"
        )
b2sums=('e9b0e8a338f2c5b37991a3f073c1bdfbb126ce296dc31a81decee2ec96727ca6a28c9b43e8c29b08e9e61be6927a9ed32d297fb4cf6c4860a2b807740ee6da16'
        '069ecde58859b3d44cd687c4b6e718610cefb693ff86e66f199ebfb1b3072023ad2b6f0c28e27ef9c1ce4997f6a5b2ca0d45046996b3ff35a4aeaeb1a7cf9421'
        'ad88bc6c1e3c8183a313b5eec42f98d6956afea349feff34a86e4536c9921fa99d2594282caf27de8ebb7ffb56376ed2e76d572227bfd6d8173c7bb1f01e23b8'
        '6f70e90359a14e4839d9a2683debb88850e5dd387add911ad68fd87e5512cfcdd435da63e1e370358153673fd5a72a9b1e9c94f1979edb7948b4da8c82407bad'
        '34dacfc4f338b68ecbb449e4726dc77a6876aae1c4ac31e0df4526a4df237d43ff3dcdd1d77d9266fb74d96f36b36fb93bbf1992e827504a313fdd1f3bfaf0ed'
        '0b782de320b3e459380cd618d5db2f3998a6dae879a84a3e4c58b1c61ecb1109f7a63485c2d6c77682eb62ba4a4aa4763a1f25eadde52486f1ce481acbf02504'
        '3fb051162e4dfc5aca3d4f41ebea18ac85d661f0ebba056a807a2a6ecf34ca117a11aeb286790f5ea6f9c6528d6b6981076da405ea0992ce8870bbe6951bdc2d'
        '040363cea9b3492f8a0f8daba44c179c871ba691dea688c15f3ad6994f78d530b4f74b283b9c64e4f5a2b1268805e60d4ea154d3dc8246200c50907054f5b5ef'
        '67cdb7e097bbb46da5cf04708bc2858b080d1a85742afc4c088da3e4e3fdeb6e4c51240fc5a6b9a1c7d927b30b3d251236e025ee4e5496142a7716d4ba51b82c'
        '822300e5eaf1964cd3e18efaf445b41f51212bec12db10e8963a86f185f0f460691efbb4e7dbeda57b2c5366784b99152c2df01b0d3686fb86bc44db289f7dab'
        '025213998583972e7551bd7bd7376ab65857e28d4338fab60ae792a6b3bd48983aec77e5143baaa63d4f3feb7cd590c4bded529c410e4d18f2b8c5813f25daa3'
        'd9cad0cef682927c07e3f7398b6e57b21b68f9069b99fab363d0e3f329337f25fafa216a82a431ee23a2de3f67a0ed68d024c1a932b76f58aeb5e9a49cfe5e6e'
        'f3bdbaac5dbe9384571fe5ec14d2d25035f227a977c25349b8188e7343804e3973b898b44c34f9abe9318666294f4fdfe780fd516dcbdb29c4ac52f6d0ed6cad'
        '43937dd83705b5ab62ae02cf1d043426c82f37e600afe06a287706e8450b596b84cc23138fbda31d67b9a2206ebfdc69754e329e7621075cbf480691f7d61871'
        '76c816df10aceec8f1a7d1356220eb3f00b16fac455e84eb8aefe76db29cd037dc74fb5cfa344b8d283b188951bd100c26e351ce2e27c16c836a547fe2c99e46'
        '417cd957f188b2b06e41d5413bea5f13481c6d5bfa8f184157379d5ac2afa9ba6f7ebc966856f50603f89b9173b6fbfdb3ccf4e3cc0b1bedb53f935591e4a35c'
        '8bb71fbec3deece7bd0f9084e20ef5853812e71e2ebcd43011f7779499cbb99c7a8bc5c618d8ef9f55e5ce54c9fc4a5f4d3167bb63f9821a68889f9f3e1386f5'
        '08f4746882b927bdff6b728630cf1e04a2b79924f694ca2d841e3115c3399feb87a8d363e4d2a0f59179c109cb6be6e840f912aadd44abb0bdb35afd2838cc4d'
        'ab35d6663b864449d46da4a9e1c51e11956ff4c38e16db58c831b71f7b964fc25b0283122dbc8aa0549f240f01c4a910fb5c6c82937258c6b736c05b54bcf768'
        '8eef73575981d10a6a8734afc0e284ec7125db24bf666ff943938a4df87dedbd9ac622ea51bb71b5aaff7b1cc75627258bcfdc8659b915c09c82d3561fde1f62'
        '71768899e631c5293d5fb8bcb237ca54f880913b6400d445c8a0322cb69801fe85b94b1293306e2f33fac6067cbd892c4665b9563bdc9ff4df5be245c7e7108f'
        '8232c6a10fd1f608304982ae7f03eb8afc663be76cdc00aee46ecb58de838e21fdc8673841266ccd00153263f7b15b59dcd1fc6ece86834509d7ccb2cacf08fa'
        'ce0dd5121e814e0fcd79d68362c80a83bfe70f970be9d5d6f6fe5f6a56ed3f041be4d560aaf02225c3ce7c457dc63bc3adf0709d4b89a81c18184ff5341eb5d3'
        'b8a64accada87ee5be989c5307805610c9b5c0327bc107aab237ac3225dd9e4c51b6c79a2a7de15fe187d3c32d7cbe1c462f9b0e9fb5d5a55a74236c7061e96e'
        '85aeb5920ee5879848be4057324153a077fe907bed527ed8f9b80a3c5ee1ef64786f63ee2999f5ba74e80a43e99ded3280ce27759c1f7b73259a6e2b5e584aa8'
        '58a94409205f7b670ab5745b8cbc234a38efd6a6217cef4efb7e397f091092e3e0c7790706b0a42accaa83d7509b8e244a98b9f0ba78349ee85f3164745c3501'
        '80da2c341d8564a47bc460fcdaf9196ac3bb77f0f2ba56bd71089e80e7481728a3ccbdcfcbc3bf70a9c9e5d9d9b01f2ca6615b67c7ab61003808ce00f6545ba3'
        '651de880cefd51665d854414c451cc80a33ed8f34e7559a95514abd81a2f58348c37dd75f272468eefd56562ba8c99093a6dd9af3ea57796a9db15164a40eda3'
        '7e41fc3a95073008ca2d71c2266d6d1a17af7803d493b447d40b15a86184c8ce3728b8d3d36765d408b1c46633d1bfa980d878cbac2e04b51ef518d44dfb7295'
        '2cdcf9ab03eb92f384caf1a2d90f82c75f880cb6286811e83217c883e421c116e7844ca193a010dc35e12eec46ede3663171a2f45f660ef5a8be95c474f61bfc'
        '7cae5e42b6e16f3c4bf64dca3c7573c1b552424ff70bb6da0a21f121b53b2546b239c87953a090cd90f46a1c3c124e2fe19c560b1830b11334f8e64c92fb614d'
        'a45b2a53b6725dfd4780049a7522befe49c2a0c4efa4fb1dcb5cf53c7af18d329d2ba02aa6ac150342a3e66a46fd17f5e6e76a8db15c677a237edbb5cf4f5af7'
        '4c178d330117886848d232372a25ecf5cac46ad48a6fed580957d295eb1c4266836f4f807593d381f9089b2078c4185ba972f697ab353a850ebf35b6f140a4ac'
        '8203bb062d72559da908a5020963503303c0aaa4a2ab61e57cfb713f58de40f1cb50b8b6dfbeec3a9addc41cbec5ae17fbf57230c3614f9b69fe6b0c55bf3fad'
        '74a51f04237fba3caa25b2e0d49659f2e8330ce82288de866943d06b53690f31d48a77a4dd2e57db1f435b715fbca792268f2e191ffb59e57170d327ed41ac0a'
        'e1d03f68918d03f980f4c2dd966e3788afe63f14e2d18dbd4dab2cdbfa1253e4823c0f5daa3a579e47319a3c2af35bc5af0a390e2ba91fe7621f6db8b1a60994'
        '5a5a61ccb7e2e343fb6de2e3426688485a2f4ad65d4b001d8bd542907fd8ceb9315da7fd9e5f89a5aa6210edcd5f334c73657fc16349000d6f6a394303e22000'
        '617b1bacb05006385d2ff5198f297a0af7ce004148e62f7f90721f093fdf6445d0024039e1aa6bfd623276f80ed6922ce62c6b2e3b5f058230e26da2ef84273f'
        '51b1324506179f7fadd8bc187eb8db939494483597b0b7b63909cec66f4e94b27888ccfa926bbd2ff8b0e80108ecc373118c202a177fc2ebd4f5231f87f09a83'
        '92cde696eec00e6758b58e73e8bc60ad1a73bb2a18d4fdfd24a19b5be715305a047943a02d94a9703c101ca0c769dbeb816f1f28809345bae0fec42fbc27bb34'
        'dede4f0774159243f87121e4d53107bb9de31f9658823fc7ab02124974b87defecf3ab0f2edf6779f2fe1ca437f16f83bf193cf3143fd5eb3a686b731319c11f'
        'ce82294e480ad42f0001c799fd8131b60024b6097653f3c57564c75e54596616e376f0d7f1cf4e54d8c302a61ef164b4323f795bfa19b2c13ab9e927d37f1600'
        '3eed24ef313c30c6e8fa69d3f88b1cf827b22fc90c144fa994433cfc5f0a9476174b418be267e16f2c3425c7f6f3ca108151f180e7d9b040f6ff88a39a05ecad'
        'd723fcc6cce65aa296bc519a07a5d003122ad698a73a3d046dac3780ea5a00fef28f78da251bb46f80f2e0577baa26a6ae13cabf525f22a7a742435e95716dae'
        'f25f01c5b27dced202fe76c1717b9eaec65dfa5f28db1910529f60f5ec21cc89c1a15df26c2dd09066a0d89e3f7d87c790e7886c3c2f0978a25f5ec7d1236099'
        '2aff3bb0804a1860bc95e25433b10f11c185bb954a2e9dc6fbee912d8d453498f9140d516ea4f31fc545861f266400db5d830092dbe21a48b22a07fd3d62a393'
        'e3302d903d053f25aa666d572f74a8bbd3b65dde40eedcbf46e537ceb2294ac22b3772087fce04c4a780c2f18e855179c6ddc8af12d72a89b82957ce09deb52f'
        '4bd44cbe85c53902b8a360509703e3d38e8a5da75dd2c534a77f03ce6440632f6c83c92939069c60473c88ffb3abab0fbf11e39271f44f813b9f6432ea5f9a6b'
        'b01c79202a2ddc6e6e3e2b97f767f5535e29213bd675238fad20f5ac26b639a111424a3d2861fe2e760b73a1d3c1d909e0360390caf1f21a6fc169b0bee4d665'
        '222ff44ad3cdbb0778074db1cbcf0fc41815ac712be16c8d4f6e82d1cb310989aef4e9537d44614bfefe404ee3acaedf29ab1366336b85b333e1df33cd98519e'
        'a56efdaae0344726debf5b74846edce8df7aa2357fbc7a05a3d369d1f457b02934a0d0ce2330072e03f1ac901e06e333c9393f795c761f8440307e7649ed5596'
        '9b1366ed5da56c77a60f9a174115a596e8466015e23dfc61ed3f4df27976dd0a35832b8fa454be9979b9ab6fdd3cf31cb35f446f8f0ef878b18c1f871f0d4ac0'
        'b9309da09b165fb57e83f84e3584d2479bd3336ed86e181e5df2d27daa92bd55d03d7f3fc226f03696af5f0f32d8e0e7ecd26ae7e50eed0200d0b0feaad07efb')

prepare() {
  cd "${_pkgname}-${_pkgver}"
  sed -i 's/-Werror//' Makefile
  sed -i 's/ncursesw5-config/ncursesw6-config/' Makefile
  sed -i 's/shell git/shell false/' Makefile
  sed -i 's/-Os/-O3/' Makefile

  # Fix filenames
  sed -i 's|cataclysm-dda|cataclysm-bn|' CMakeLists.txt
  sed -i 's|TARGET_NAME = cataclysm|TARGET_NAME = cataclysm-bn|' Makefile
  sed -i 's|cataclysm.a|cataclysm-bn.a|' Makefile
  sed -i 's|cataclysm.a|cataclysm-bn.a|' tests/Makefile
  sed -i 's|cataclysm-dda|cataclysm-bn|' src/path_info.cpp

  # Fix version
  sed -i 's|VERSION = unstable|VERSION = 2021-12-06-1544|' Makefile


  # # # Hotfixes
  #echo "Applying hotfixes"


  # # # Various fixes for bugs I came across
  # # Ammo fixes
  echo "Applying ammo fixes"
  # Fix mulitple inconsistent ammuntion names and handloaded status.
  patch -Np1 -i "$srcdir"/ammo-01_inconsistent-ammo-names.patch

  # Set a fixed loudness of 20x66mm shotgun shells like that of other shotguns:
  # Other shotguns have fixed loudness to work around how the short range factors causes them to be far quieter than one would otherwise expect.
  patch -Np1 -i "$srcdir"/ammo-02_fix-20x66mm-loudness.patch

  # Change reloaded_50bmg to be based on 50bmg:
  # The id and description make it pretty clear that reloaded_50bmg is not supposed to be based on Match rounds.
  patch -Np1 -i "$srcdir"/ammo-03_fix-reloaded-50bmg.patch

  # Replace several ammo fragmentation and explosive effects that are missing in BN with other ones.
  patch -Np1 -i "$srcdir"/ammo-04_fix-missing-ammo-frag-effects.patch

  # Fix .22 casings not stacking when every other casing stacks.
  patch -Np1 -i "$srcdir"/ammo-05_22-casings-can-stack.patch

  # Fix ammo ordering so as to not prevent those items being modded.
  # Having copy-from items occuring earlier in a json than the item being copied from prevents items based on it being modified.
  patch -Np1 -i "$srcdir"/ammo-10_ammo-order-fix.patch


  # # armor fixes
  echo "Applying armor fixes"
  # Fix Ankle Ammo Pouch to not look like a backpack:
  # SDG added a tile for ammo pouches to bypass this bug, but this fix still makes sense.
  patch -Np1 -i "$srcdir"/armor-01_ankle-ammo-pouch-is-not-a-backpack.patch

  # Fix fingerless survivor gloves losing base warmth:
  # They lose warmth already from the lack of coverage, no need to double up.
  patch -Np1 -i "$srcdir"/armor-02_fix-survivor-fingerless-gloves-warmth.patch


  # # bionics fixes
  echo "Applying bionic fixes"
  # Fix npc not being able to install some additional CBMs:
  #  ie, soporific inducer, gasoline fuel cell, enhanced hearing, surgical scalpels.
  patch -Np1 -i "$srcdir"/bionics-01_npc-can-use-more-bionics.patch


  # # food fixes
  echo "Applying food fixes"
  # Fix several foods not being marked as the correct material:
  # This prevents odd outcomes such as carnivores drinking almond/soy milk and eating peanut butter.
  patch -Np1 -i "$srcdir"/foods-01_fix-food-materials.patch


  # # itemgroups fixes
  echo "Applying itemgroup fixes"
  # Stop police and SWAT carrying 4.6mm magazines despite having no compatible weapons:
  # The H&K UCP was removed from the base game some time ago.
  patch -Np1 -i "$srcdir"/itemgroups-01_hk46-is-milspec.patch

  # Fix the pepperjack beef and burrito bowl MREs never dropping:
  # They weren't in the itemgroups for MREs or soldier class.
  patch -Np1 -i "$srcdir"/itemgroups-02_add-missing-mre.patch


  # # monster fixes
  echo "Applying monster fixes"
  # Prefix medical zombies with "zombie" like other zombies:
  # It just felt weird seeing "nurse" in the enemy list.
  patch -Np1 -i "$srcdir"/monsters-01_medical-zombies-called-zombies.patch


  # # mutation fixes
  echo "Applying mutation fixes"
  # Light Step feels too powerful in Bright Nights.
  patch -Np1 -i "$srcdir"/mutations-01_nerf-lightstep.patch

  # Fix Evacuee 3 background 3 being player visible:
  # It was missing "player_display": false
  patch -Np1 -i "$srcdir"/mutations-02_fix-evac3-background-visible.patch


  # # recipe fixes
  echo "Applying recipe fixes"
  # Fix brioche bun missing a cooking time:
  # It was missing a cooking time entirely resulting in instant cooking. Talk about quick rise bread.
  patch -Np1 -i "$srcdir"/recipes-01_fix-brioche-cooking-time.patch

  # Fix reloaded 45-70 rounds and reloaded dragon shot not allowing dismantling when every other non-caseless round does.
  patch -Np1 -i "$srcdir"/recipes-02_4570-dragon-can-be-dismantled.patch


  # # terrain and overmap fixes
  echo "Applying terrain and overmap fixes"
  # Fix Quiverfull house to have the correct stairwell direction:
  # It was set to < for up, and not > for down.
  patch -Np1 -i "$srcdir"/terrain-01_quiverfull-house-correct-stairs.patch

  # Fix tacoma barn doors being placed in the same spot twice:
  # This enables the southeast barn door to be placed properly.
  patch -Np1 -i "$srcdir"/terrain-02_tacoma-barn-door-position.patch

  # Fix missing floor in the tacoma clinic:
  # The hospital is still a mess. :/
  patch -Np1 -i "$srcdir"/terrain-03_tacoma-clinic-add-missing-floor.patch

  # Fix lumbermill gasoline being spilled instead of being inside the gas pump:
  # The gas pump was placed on top of a tile that didn't allow items inside, causing the gasoline to be shunted to the next valid one.
  patch -Np1 -i "$srcdir"/terrain-04_lumbermill-gasoline-not-spilled.patch

  # Fix community garden liquid fertilizer being in a pit instead of in the storage tanks:
  # I'm pretty sure that having it all dumped in a pit was not intentional.
  patch -Np1 -i "$srcdir"/terrain-05_community-garden-fertilizer-not-spilled.patch

  # Fix some doors being unusable by npcs (incorrect door flag):
  # The DOOR flag is for terrain that can be opened, not those already open.
  patch -Np1 -i "$srcdir"/terrain-06_fix-doors-for-npcs.patch

  # Re-hide something that feels like spoilers.
  patch -Np1 -i "$srcdir"/terrain-07_rehide-redacted.patch

  # Set the overmap note for Derelict Shed to s to better match use of the first letter.
  patch -Np1 -i "$srcdir"/terrain-08_derelict-shed-is-s.patch

  # Fix npcs unable to drink from firestation and shelter basecamps wells:
  # They were missing the water_well blueprint_provides.
  patch -Np1 -i "$srcdir"/terrain-09_make-firestation-shelter-wells-npc-drinkable.patch


  # # tool fixes
  echo "Applying tool fixes"
  # Mark the foldable plastic bottle and steel water bottle as containers:
  # Being counted as tools didn't seem to fit their role.
  patch -Np1 -i "$srcdir"/tools-01_foldable-bottle-is-container.patch

  # Fix blood draw kit being categorized as a weapon:
  # Upstream changed item templates, so this sets it back to be a tool.
  patch -Np1 -i "$srcdir"/tools-02_vacutainer-is-not-a-weapon.patch

  # Fix electric shears not using batteries nor charging via UPS:
  # Item was unusable without this patch.
  patch -Np1 -i "$srcdir"/tools-03_shears-use-light-battery.patch

  # Normalize the manhack volumes to that of the base grenade/explosive:
  # I don't see how a c-4 manhack could be 1/4 the volume of a stick of c-4.
  # Grenade hacks were also thrice as big as the base grenade.
  patch -Np1 -i "$srcdir"/tools-04_normalize-drone-volume.patch


  # # vehicle fixes
  echo "Applying vehicle fixes"
  # Replace the portable generator twin engine with a large 1 cylinder:
  # This way it can actually function as is.
  patch -Np1 -i "$srcdir"/vehicles-01_portable-generator-engine.patch



  # # Uncategorized for now
  echo "Applying uncategorized fixes"
  # Fix rubber items dismantling into 10x item volume of rubber.
  patch -Np1 -i "$srcdir"/etc-01_fix-rubbersplosion.patch

  # Add price_postapoc to a number of items that did not have one set.
  patch -Np1 -i "$srcdir"/etc-02_add-missing-price-postapoc.patch
  
  # Revert the book changes for now.
  patch -Np1 -i "$srcdir"/etc-03_revert-book-revamp.patch
  rm data/json/items/book/bloat.json


  # # # Various other fixes for bugs I came across that modify src
  echo "Applying source code fixes"
  # Fix radio, e-ink reader music, tactical tonfa not working with UPS.
  patch -Np1 -i "$srcdir"/jc_radio-can-use-ups.patch

  # Fix ammo loudness mulitplying by six instead of two.
  patch -Np1 -i "$srcdir"/jc_ammo-loudness-ap-times-2.patch

  # Fix smoker racks not accepting bionic firestarter.
  patch -Np1 -i "$srcdir"/jc_allow-bio-firestarter-on-smoker.patch

  # Fix Non-Player facton NPCs from becoming sleep deprived.
  patch -Np1 -i "$srcdir"/jc_stop-non-faction-npc-sleep-depirvation.patch

  # Fix Non-Player facton NPCs from becoming malnourished.
  patch -Np1 -i "$srcdir"/jc_stop-non-faction-npc-malnourishment.patch

  # Fix NPCs preferring tables to cots or woodstoves to the floor.
  patch -Np1 -i "$srcdir"/jc_stop-sleeping-on-tables.patch

  # Allow the hacker_laptop to utilize the extra functions.
  patch -Np1 -i "$srcdir"/jc_allow-hacker-laptop.patch

  # Revert the Infection Immune Trait and Revert Infection Resistant to as before. Also keep Truthteller.
  patch -Np1 -i "$srcdir"/jc_restore-removed-traits.patch

  # Expand the overmap tiles for the miltiary base to be less MMMM
  patch -Np1 -i "$srcdir"/jc_more-military-base-overmap.patch

  # Allow npcs to pull food from the camp larder at the full range of tiles camp actions can be assigned from. 
  patch -Np1 -i "$srcdir"/jc_npc-eat-from-further-camp.patch


  # # # Additional changes
  echo "Applying gynoid and vampire patch"
  # Add gynoid and vampire mutation lines. might require vampire stuff redone mod.
  patch -Np1 -i "$srcdir"/custom.patch
}

build() {
  cd "${_pkgname}-${_pkgver}"

  #export CFLAGS="$CFLAGS -fPIE"
  export CXXFLAGS="$CXXFLAGS -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

  # tests "ifdef TILES" so "TILES=0" will enable tiles!
  # DYNAMIC_LINKING appears to be a windows flag?
  make PREFIX=/usr RELEASE=1 USE_XDG_DIR=1 BACKTRACE=0 LTO=1 LOCALIZE=1 LANGUAGES=all
  make PREFIX=/usr RELEASE=1 USE_XDG_DIR=1 BACKTRACE=0 LTO=1 LOCALIZE=1 LANGUAGES=all TILES=1 SOUND=1
  ./lang/compile_mo.sh
}

package_cataclysm-bn() {
  cd "${_pkgname}-${_pkgver}"

  make DESTDIR="$pkgdir" PREFIX="/usr" RELEASE=1 USE_HOME_DIR=1 LTO=1 LOCALIZE=1 LANGUAGES=all install

  # Docs
  install -d "$pkgdir/usr/share/doc/cataclysm-bn"
  cp --reflink -r doc/* "$pkgdir/usr/share/doc/cataclysm-bn"
  # undo symlink
  rm "$pkgdir/usr/share/doc/cataclysm-bn/JSON_LOADING_ORDER.md"
  cp --reflink 'data/json/LOADING_ORDER.md' "$pkgdir/usr/share/doc/cataclysm-bn/JSON_LOADING_ORDER.md"

  # License
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # Languages
  cd lang/mo
  for i in *; do
    install -d "${pkgdir}/usr/share/locale/${i}/LC_MESSAGES"
    cp --reflink "${i}/LC_MESSAGES/cataclysm-bn.mo" "${pkgdir}/usr/share/locale/${i}/LC_MESSAGES"
  done

  # Help
  cd ./../..
  cp -r --reflink --no-preserve=ownership "./data/help" "${pkgdir}/usr/share/${pkgname}/"

#  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}

package_cataclysm-bn-tiles() {
  pkgdesc="A graphical post-apocalyptic roguelike."
  depends=('cataclysm-bn' 'sdl2_image' 'sdl2_ttf' 'freetype2' 'sdl2_mixer')
  cd "${_pkgname}-${_pkgver}"

  make DESTDIR="$pkgdir" PREFIX="/usr" RELEASE=1 LTO=1 LOCALIZE=1 LANGUAGES=all TILES=1 SOUND=1 install


  # Icon
  #install -D 'data/osx/AppIcon.iconset/icon_128x128.png' "$pkgdir/usr/share/icons/hicolor/128x128/apps/$pkgname.png"
  #install -D 'data/osx/AppIcon.iconset/icon_128x128.png' "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -D "${srcdir}/icon_128x128.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/$pkgname.png"
  install -D "${srcdir}/icon_128x128.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -Dm644 "${srcdir}/$pkgname.desktop" "${pkgdir}/usr/share/applications/$pkgname.desktop"

  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"


  # Tileset
  mv "$srcdir/cataclysm-dda-tileset_undeadpeople-master" "$srcdir/undeadpeople"
  cp --reflink -r "$srcdir/undeadpeople" "$pkgdir/usr/share/cataclysm-bn/gfx"
  rm -rf "$pkgdir/usr/share/cataclysm-bn/gfx/MSX++UnDeadPeopleEdition"

  #mv "$srcdir/cataclysm-dda-mod_battle-maid-redone-tileset-master" "$srcdir/battle-maid-redone-tileset"
  cp --reflink -r "$srcdir/cataclysm-dda-mod_battle-maid-redone-tileset-master/battle-maid-redone-tileset-pt1" "$pkgdir/usr/share/cataclysm-bn/mods"
  cp --reflink -r "$srcdir/cataclysm-dda-mod_battle-maid-redone-tileset-master/battle-maid-redone-tileset-pt2" "$pkgdir/usr/share/cataclysm-bn/mods"


  # Sound
  mv "$srcdir/cataclysm-dda-soundpack_jcsoundpack-master" "$srcdir/jcsoundpack"
  cp --reflink -r "$srcdir/jcsoundpack" "$pkgdir/usr/share/cataclysm-bn/sound"

  # Music
  mv "$srcdir/cataclysm-dda-musicpack_coag-musicpack-master" "$srcdir/coag-musicpack"
  install -Dm644 "$srcdir/coag-musicpack/musicset.json" "$pkgdir/usr/share/cataclysm-bn/sound/jcsoundpack/musicset.json"
  cp --reflink -r "$srcdir/coag-musicpack/music" "$pkgdir/usr/share/cataclysm-bn/sound/jcsoundpack"


  # hack: remove overlapping files
  cd "$pkgdir/../cataclysm-bn"
  find . -type f -exec rm -f "$pkgdir"/{} \;
  cd "$pkgdir"
  find . -type d -empty -delete
}