PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Max Zhao <alcasa dot mz at gmail dot com>
# Contributor (AUR): Leonard König <leonard.r.koenig at googlemail dot com>
# Contributor (AUR): George Rawlinson <george@rawlinson.net.nz>

# # I maintain this because:
# AUR version uses /usr/share/games

pkgname=endless-sky
pkgver=0.9.8
pkgrel=2
arch=('i686' 'x86_64')
url="https://endless-sky.github.io/"
depends=(openal libpng glew hicolor-icon-theme libjpeg-turbo sdl2 libmad)
makedepends=(scons)
optdepends=('endless-sky-high-dpi: high resolution graphics assets'
            'endless-sky-editor: map editor')
license=('GPL3' 'CCPL' 'custom:public domain')
pkgdesc="A space exploration and combat game similar to Escape Velocity"
source=(
        "$pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/v$pkgver.tar.gz"
        $pkgname.desktop
        )

sha512sums=('521026cb70372fd380b14a1a1d296f86015e5999dc233f4d9c05d958092e1f3982d2f12e913a435d5827fb45945bd4b60bbae293c2c90685024cdae96e352078'
            '8948a286a84df381171888ab44da877476594b1f0877a3e54699a072fc0a85713767af7e1edbaf24d9fc8de49f1fe3d8e7955b1908eb2d02a5ea6d1027834527')

build() {
  cd $pkgname-$pkgver
  scons -j 2
}


package() {
  cd $pkgname-$pkgver

  # Install executable
  install -Dm755 endless-sky $pkgdir/usr/bin/$pkgname

  # resources
  ## They explicitly want this path. Although one could workaround with '-r' param
  install --directory "$pkgdir/usr/lib/$pkgname"
  cp -rf data images sounds "$pkgdir/usr/lib/$pkgname/"
  install -Dm644 credits.txt "$pkgdir/usr/lib/$pkgname/credits.txt"
  install -Dm644 keys.txt "$pkgdir/usr/lib/$pkgname/keys.txt"

  # .desktop
  install -Dm644 $srcdir/$pkgname.desktop $pkgdir/usr/share/applications/$pkgname.desktop

  # icons
  for res in 16 22 24 32 48 256; do
    install -Dm644 \
      "${srcdir}/${pkgname}-${pkgver}/icons/icon_${res}x${res}.png" \
      "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/${pkgname}.png"
  done

  # mac icon directory has additional icons [128+512px]
  for res in 128 512; do
    install -Dm644 \
      "${srcdir}/${pkgname}-${pkgver}/icons/endless-sky.iconset/icon_${res}x${res}.png" \
      "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/${pkgname}.png"
  done

  # manpage
  install -Dm644 -t "${pkgdir}/usr/share/man/man6" endless-sky.6

  # copyright
  install -Dm644 copyright "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}