PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Max Zhao <alcasa dot mz at gmail dot com>
# Contributor (AUR): Leonard König <leonard.r.koenig at googlemail dot com>

# # I maintain this because:
# AUR version PKGBUILD is cluttered

pkgname='endless-sky'
pkgver=0.9.8
pkgrel=1
arch=('i686' 'x86_64')
url="https://endless-sky.github.io/"
depends=('sdl2' 'libjpeg-turbo' 'glew' 'openal' 'hicolor-icon-theme' 'libmad')
makedepends=('git' 'scons')
license=('GPL3' 'CCPL' 'custom:public domain')
pkgdesc="A space exploration and combat game similar to Escape Velocity"
source=(
        ${pkgname}-${pkgver}.tar.gz::https://github.com/endless-sky/endless-sky/archive/v${pkgver}.tar.gz)

sha256sums=('69078c67656709646deb0c46fd960aa905601c23bb47c1696b0962ae8dff6d1e')

build() {
	cd $pkgname-$pkgver
	scons
  # gzip manpage
  gzip -f endless-sky.6
}


package() {
	cd $pkgname-$pkgver
	# Install executables
	install -Dm755 endless-sky ${pkgdir}/usr/bin/$pkgname

  # resources
  ## They explicitly want this path. Although one could workaround with '-r' param
  install --directory ${pkgdir}/usr/share/games/${pkgname}
  cp -rf data images sounds ${pkgdir}/usr/share/games/${pkgname}/
  install -Dm644 credits.txt ${pkgdir}/usr/share/games/${pkgname}/credits.txt
  install -Dm644 keys.txt ${pkgdir}/usr/share/games/${pkgname}/keys.txt

  # icons and .desktop
  _idir=endless-sky.iconset
  _iddir=${pkgdir}/usr/share/icons/hicolor

  install -Dm644 icons/icon_16x16.png ${_iddir}/16x16/apps/${pkgname}.png
  install -Dm644 icons/icon_22x22.png ${_iddir}/22x22/apps/${pkgname}.png
  install -Dm644 icons/icon_24x24.png ${_iddir}/24x24/apps/${pkgname}.png
  install -Dm644 icons/icon_32x32.png ${_iddir}/32x32/apps/${pkgname}.png
  install -Dm644 icons/icon_48x48.png ${_iddir}/48x48/apps/${pkgname}.png
  install -Dm644 icons/icon_256x256.png ${_iddir}/256x256/apps/${pkgname}.png
  install -Dm644 endless-sky.desktop "${pkgdir}/usr/share/applications/${pkgname}.desktop"

  # manpage
  install -Dm644 endless-sky.6.gz ${pkgdir}/usr/share/man/man6/${pkgname}.6.gz

  # copyright
  install -Dm644 copyright ${pkgdir}/usr/share/licenses/${pkgname}/copyright
}