blob: 285b950a02984061bf1daf6be1888b52f8d4dbab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): George Rawlinson <george@rawlinson.net.nz>
# Contributor (AUR): Max Zhao <alcasa dot mz at gmail dot com>
# Contributor (AUR): Leonard König <leonard.r.koenig at googlemail dot com>
# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
pkgname=endless-sky
pkgver=0.9.14
pkgrel=1
pkgdesc="A sandbox-style space exploration and combat game"
arch=('x86_64' 'i686' 'aarch64')
url="https://endless-sky.github.io/"
license=(
'GPL3'
'custom:CC-BY-3.0'
'custom:CC-BY-4.0'
'custom:CC-BY-NC-3.0'
'custom:CC-BY-SA-3.0'
'custom:CC-BY-SA-4.0'
'custom:public-domain'
)
depends=(
'gcc-libs'
'openal'
'libpng'
'glew'
'hicolor-icon-theme'
'libjpeg-turbo'
'sdl2'
'libmad'
)
makedepends=('scons')
optdepends=(
'endless-sky-high-dpi: high resolution graphics assets'
)
source=("$pkgname-$pkgver.tar.gz::https://github.com/endless-sky/endless-sky/archive/v${pkgver}.tar.gz")
b2sums=('5845c3b595f0feba7fc5f6ce1ead88b34e9426c3db53cf013fc67f9197d2cabad8fae39056fa6f4d6da76fceb43a9709397b95daba855d1b1ebf3c25a04ba007')
prepare() {
cd "$pkgname-$pkgver"
# binary is installed to /usr/games instead of /usr/bin
sed -i 's:games", sky:bin", sky:' SConstruct
}
build() {
cd "$pkgname-$pkgver"
export CFLAGS="$CFLAGS -O3 -flto=auto -fPIE"
export CXXFLAGS="$CXXFLAGS -O3 -flto=auto -fPIE"
export LDFLAGS="$LDFLAGS,-pie"
scons "${MAKEFLAGS}"
}
package() {
cd "$pkgname-$pkgver"
scons \
DESTDIR="$pkgdir" \
PREFIX=/usr \
install
# license
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" copyright
}
|
